VBA - Vlookup multiple rows from another sheet, paste as values - excel

Question

I've been trying to figure this out, but had to luck.
I have a list that starts on A5 on worksheet2. I need to Vlookup each item from A5 down until the last cell in column A (list will never be the same size). The data/info will be on worksheet1. Then paste (as values) the data starting in cell C5 and until the last corresponding cell in column A.
The data on worksheet1 will most likely always been in columns A:L, but this could change so i'm hoping to make it dynamic where the code can know which column the data ends. Data will always start on A1.
I'm not sure how to loop this. Looking to achieve this through VBA using a macro-enabled button I started programming.
Thanks in advance!

Answer 1

sub lookup
dim x as long, lastrow as long
lastrow = Sheet2.cells(rows.count,1).end(xlup).row
for x = 5 to lastrow
Sheet2.Range("C" & x) = worksheetfunction.xlookup arg1:=sheet2.range("A" & x), _
arg2:= Sheet1.Range("A:A"), arg3:=Sheet1.range("B:B")
next x
end sub
I think you are going to need to solidify which column you are wanting to return in order to make the VBA simple. Depending on the column I think you can loop through until you find the header you are looking for, but it would be better if it was always in the same place.
This code says, for the sheet length of sheet2, starting in c5 xlookup your key, find it on sheet 1, and return the column that has your data.

Answer 2

It seems that you are looking for a row number in Worksheet1 and then intend to transfer all available data from that row. That would be a job for the MATCH worksheet function or Find in VBA. Please try the code below.
Sub MatchAndCopy()
' 213
Dim Rng As Range ' source data
Dim Arr As Variant ' one row of data
Dim Crit As Variant ' match criterium
Dim Fnd As Range ' match found
Dim R As Long ' loop counter: rows
Dim Spike As String ' collecting failures
Set Rng = Worksheets("Sheet1").UsedRange
Application.ScreenUpdating = False ' speed up execution
With Worksheets("Sheet2")
For R = 5 To .Cells(.Rows.Count, "A").End(xlUp).Row
Crit = .Cells(R, "A").Value
Set Fnd = Rng.Columns(1).Find(Crit, LookIn:=xlValues, LookAt:=xlWhole)
If Fnd Is Nothing Then
If Len(Spike) Then Spike = Spike & vbCr
Spike = Spike & String(5, " ") & """" & Crit & """ in row " & R
Else
Arr = Fnd.Offset(0, 1).Resize(1, Rng.Columns.Count - 1).Value
.Cells(R, 2).Resize(1, UBound(Arr, 2)).Value = Arr
End If
Next R
End With
Application.ScreenUpdating = True
If Len(Spike) Then
Spike = "Transfer of the following items failed." & vbCr & Spike
Else
Spike = "Data were transferred successfully and without errors."
End If
MsgBox Spike, vbInformation, "Transfer report"
End Sub