Find column by name and convert it vba - excel

Question

How can I find in vba column by name ex. "Test1" and convert whole column to number format?
as far i manage to find the cell:
Worksheets("Sheet1").Cells.Find(What:="Test1")

Answer 1

Something like this:
Public Sub Test()
Dim r As Range
Set r = FindColumn("Test1")
If Not r Is Nothing Then
r.NumberFormat = "#,##0.00"
End If
End Sub
Public Function FindColumn(HeaderName As String) As Range
Dim FndCol As Range
With ThisWorkbook.Worksheets("Sheet1")
Set FndCol = .Cells.Find(HeaderName, .Cells(1, 1), xlValues, xlWhole)
If Not FndCol Is Nothing Then
Set FindColumn = FndCol.EntireColumn
End If
End With
End Function

Answer 2

Data Column Number Format
This solution will print the range addresses at the various stages of the code to the Immediate window (CTRL+G).
For example, in the range A1:J10 containing data, if cell C1 is equal to Test1, it will apply the number format to the range C2:C10.
Option Explicit
Sub applyColumnNumberFormat()
Const wsName As String = "Sheet1"
Const HeaderRow As Long = 1
Const Header As String = "Test1"
Const nFormat As String = "#.00"
Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
Dim ws As Worksheet: Set ws = wb.Worksheets(wsName)
Dim hrg As Range: Set hrg = ws.Rows(HeaderRow) ' Header Row Range
Debug.Print "Header Row Range: " & hrg.Address(0, 0)
Dim hCell As Range ' Header Cell Range
Set hCell = hrg.Find(Header, hrg.Cells(hrg.Cells.Count), _
xlFormulas, xlWhole)
If Not hCell Is Nothing Then
Debug.Print "Header Cell Address: " & hCell.Address(0, 0)
Dim lCell As Range ' Last Non-Empty Cell Range
Set lCell = ws.Cells.Find("*", , xlFormulas, , xlByRows, xlPrevious)
Debug.Print "Last Non-Empty Cell: " & lCell.Address(0, 0)
Dim drg As Range ' Destination Range - Occupied Cells Below the Header
Set drg = hCell.Resize(lCell.Row - hCell.Row).Offset(1)
Debug.Print "Destination Range: " & drg.Address(0, 0)
drg.NumberFormat = nFormat
Else
Debug.Print "Header '" & Header & "' not found."
End If
End Sub

Answer 3

The following code assumes your column headings are on row 1.
The Find function returns a range object. You can use the Column property of the range to identify the column you want to format.
Dim r As Range
Dim col As Integer
Set r = Worksheets("Sheet1").Rows(1).Find(What:="Test")
If r Is Nothing Then
'Column heading not found
Else
col = r.Column
Worksheets("Sheet1").Columns(col).NumberFormat = "0.00"
End If