Save cell changes in threaded comment VB - excel

Question

I would like to "Save" the previous info from the cell in a Threaded Comment when i change the value.
This script does that if a cell is empty. If a cell is not empty, then i would like it to save the last value in a threaded comment, not replacing the old comment, but making it into a discussion like it is supposed to be.
Can anybody help me with that? Attached is my code that makes a threaded comment.
Private Sub Worksheet_Change(ByVal Target As Range)
Const sRng As String = "A5:AQ155" ' change as required
Dim sOld As String
Dim sNew As String
Dim sCmt As String
Dim iLen As Long
If Not Intersect(Target, Me.Range(sRng)) Is Nothing Then
Application.EnableEvents = False
With Target
sNew = .Value2
Application.Undo
sOld = .Value2
.Value2 = sNew
Application.EnableEvents = True
sCmt = "Sist endra: " & Format$(Now, "dd Mmm YYYY hh:nn:ss") & " av " & Application.UserName & Chr(10) & "Tidligere info: " & sOld
If .CommentThreaded Is Nothing Then
.AddCommentThreaded sCmt
Else
.AddCommentThreaded sCmt
End If
With .CommentThreaded.Shape.TextFrame
.AutoSize = True
.Characters(Start:=iLen + 1).Insert IIf(iLen, vbLf, "") & sCmt
End With
End With
End If
End Sub

Answer 1

Please try this code. It should just about do what you want although it uses the Note rather than the Comment. The new "Note" equals and replaces the former "Comment". Soo how you like it.
Private Sub Worksheet_Change(ByVal Target As Range)
' 199
Const sRng As String = "A5:AQ155" ' change as required
Dim sOld As String
Dim sNew As String
Dim sCmt As String
Dim iStart As Integer ' first character position
Dim iEnd As Integer ' lastcharacter position
If Not Intersect(Target, Range(sRng)) Is Nothing Then
Application.EnableEvents = False
With Target.Cells(1)
sNew = .Value2
Application.Undo
sOld = .Value2 ' get previous value
.Value2 = sNew
On Error Resume Next
With .Comment
sCmt = .Text ' get previous Note
.Delete
End With
On Error GoTo 0
If Len(sCmt) Then sCmt = vbLf & sCmt
sCmt = "Sist endra: " & Format$(Now, "dd Mmm YYYY hh:nn:ss") & " av " & _
Application.UserName & Chr(10) & "Tidligere info: " & sOld & sCmt
With .AddComment(sCmt)
Do
iEnd = iEnd + 1
iStart = InStr(iEnd, .Text, " av ", vbTextCompare) + 4
If iStart = 4 Then Exit Do
iEnd = InStr(iStart, .Text, Chr(10))
If iEnd = 0 Then iEnd = Len(.Text)
.Shape.TextFrame.Characters(iStart, iEnd - iStart).Font.Bold = True
Loop
End With
End With
Application.EnableEvents = True
End If
End Sub
The little game at the end which boldens the user name is intended to show how you might identify and modify part of the comment's text.