Print arglist same way as :ls - vim

Question

:ls
1 h "~/Documents/trash/practical-vim" line 1
3 h "LICENSE.txt" line 1
4 h "auto_complete/sea-shells.txt" line 1
5 h "files/a.txt" line 1
6 h "files/b.txt" line 1
output of ls command, you can use :b3 to switch to buffer 3, what I want is the same output for :args command, but what I get:
:args
[auto_complete/webapp/public/index.html] ex_mode/practical-vim.html files/mvc/index.html global/episodes.html
i.e. arglist params are printed in one line, which makes usage of :argument3 (to switch to third file in arglist) basically impossible if amount of files is huge. I want these files to be printed on new line with number by which I can access these files like in :ls command.
I tried to write a simple command for this scenario:
command! Args
\ :let var_args = argv()
\ :let var_args_size = len(var_args)
\ :if var_args_size > 0 | let var_args_size = var_args_size - 1 | endif
\ :for i in range(0, var_args_size) | echo printf("%3d %s", i + 1, var_args[i]) | endfor
But:
E15: Invalid expression: argv() :let var_args_size = len(var_args) :if var_args_size > 0 | let var_args_size = var_args_size - 1 | endif
:for i in range(0, var_args_size) | echo printf("%3d %s", i + 1, var_args[i]) | endfor
I kindly request assistance either with my command or some other way to print arglist like this:
:args
1 auto_complete/webapp/public/index.html
2 ex_mode/practical-vim.html
3 files/mvc/index.html
4 global/episodes.html
so i can execute :argument3 and switch to files/mvc/index.html without counting.

Answer 1

You are way beyond the point at which nifty one-liners become liabilities.
Using a function is much cleaner:
function! Args()
let var_args = argv()
let var_args_size = len(var_args)
if var_args_size > 0
let var_args_size = var_args_size - 1
endif
for i in range(0, var_args_size)
echo printf("%3d %s", i + 1, var_args[i])
endfor
endfunction
command! Args call Args()
How about a more interactive approach?
function! Args()
let prompt = 'Select an argument:'
let arg_list = map(argv(), 'v:key + 1 . ". " . v:val')
let chosen_arg = inputlist([prompt] + arg_list))
if chosen_arg
execute 'argument ' . chosen_arg
endif
endfunction
command! Args call Args()
See :help map(), :help inputlist().

Answer 2

Just one line
command! -bar Args echo join(map(argv(), {_, v -> printf("%3d\t%s", bufnr(v), v)}), "\n")
It shows buffer number instead of argument index, so :bX to switch buffer.