How to clear bookmark data using macro in MS word - excel

Question

I am trying to update data in ms word from excel using macro. To simplify the process, I am using bookmark feature. The issue is when I ran the code, the data in bookmark gets duplicated and I see the same data points from excel in ms word multiple times. I tried to find out a solution on how to clear the data stored in bookmarks before pasting new data but the problem seems to be unresolved.
------------------CODE----------------------------
Option Explicit
Const FilePath As String = "C:\Users\Prablee.Singh\Desktop\"
Dim wd As New Word.Application
Sub ExporttoWord()
Dim doc As Word.Document
wd.Visible = True
Dim Model_Name As String
Dim Model_Description As String
Dim Model_Status As String
Model_Name = ThisWorkbook.Sheets(2).Range("A2").Value 'value from sheet1
Model_Description = ThisWorkbook.Sheets(2).Range("B2").Value
Model_Status = ThisWorkbook.Sheets(2).Range("C2").Value
Set doc = wd.Documents.Open(FilePath & "VBA Code Doc.docx")
Copy2word "Project1", Model_Name
Copy2word "Project1Description", Model_Description
Copy2word "Project1Status", Model_Status
doc.Close
wd.Quit
End Sub
Sub Copy2word(BookMarkName As String, Text2Type As String)
wd.Selection.GoTo What:=wdGoToBookmark, Name:=BookMarkName
wd.Selection.TypeText Text2Type
End Sub

Answer 1

Correct me if I'm wrong. You want to insert text to replace old bookmark? Is your bookmarks marked as range or it's only location? You can replace whole bookmark text using this sample:
Dim BookmarkRange As Range
Set BookmarkRange = ActiveDocument.Bookmarks("myBookmarkRange").Range
BookmarkRange.Text = "this text will replace the old one."

Answer 2

This problem is likely caused by the bookmark simply marking a location in the document, as shown in the top example of the screenshot below, rather than enclosing text.
To see the bookmarks go to File | Options | Advanced | Show Document Content and tick the "Show bookmarks" option.
When inserting text into an enclosing bookmark the bookmark gets deleted and needs to be replaced. This can be done by using a routine such as the one below which also checks that the bookmark exists to avoid errors.
Public Sub InsertIntoBookmark(bookmarkName As String, text As String, _
Optional targetDoc As Document = Nothing)
Dim bookmarkRange As Range
If targetDoc Is Nothing Then Set targetDoc = ActiveDocument
If targetDoc.Bookmarks.Exists(bookmarkName) Then
Set bookmarkRange = targetDoc.Bookmarks(bookmarkName).Range
bookmarkRange.text = text
targetDoc.Bookmarks.Add bookmarkName, bookmarkRange
End If
End Sub

Answer 3

Since the text, as you've said is duplicating that indicates your bookmark is a single point in the document and not a spanned range. The resultant behavor is then to add the text behind the bookmark and leave the bookmark in place. If your bookmark was a spanned range of existing text then Word would replace the text but it would also remove the bookmark.
Either way, your code must reestablish a bookmark ... that is unless you want to remove the bookmark after you have placed the new data into the document.
Try this code ...
Dim rng As Word.Range
Set rng = doc.Bookmarks("BookMarkName").Range
rng.Text = "Project Name"
doc.Bookmarks.Add "BookMarkName", rng
As I've tried to explain above, if your Word document had in the BookMarkName a placeholder of "Temp Name" the code above would replace it with "Project Name" and then reestablish the BookMareName surrounding "Project Name". If you didn't what it to reestablish BookMarkName, then just omit the last line.
If in your existing document BookMarkName is a single address point and not a span of text, the code above will still add the new text, but it will also relocate the BookMarkName range to the new span of text. And the difference here is if you don't want the BookMarkName to remain after inserting the new text, you will have to replace the last code line with ...
doc.Bookmarks(BookMarkName).Delete