VBA sum row base on different two condition and delete row - excel

Question

I would like to create a macro that will sum the unit column base by Product & DC. It will populate out the same product name, code with dc code and code without.
Sub Button1_Click()
For i = 2 to lstrow
Next I
MsgBox ("Done")
End Sub
Product
DC
Unit
ABC
0
2
ABC
1234
4
ABC
1234
4
DEF
5678
2
DEF
5678
2
GHI
9012
2
I want to the output as below:-
Product
Unit with DC Code
Unit Without DC Code
ABC
6
2
DEF
4
0
GHI
2
0

Answer 1

Sum Unique
Adjust the values in the constants section.
If you want to overwrite ('mimic' RemoveDuplicates), then just replace Sheet2 with Sheet1 and uncomment the Delete below section. Keep in mind that you won't be able to undo.
The Code
Option Explicit
Sub sumUnique()
' Define constants.
Const sName As String = "Sheet1"
Const sFirstCellAddress As String = "A2"
Const dName As String = "Sheet2"
Const dFirstCellAddress As String = "A1"
' Define workbook.
Dim wb As Workbook: Set wb = ThisWorkbook
' Write values from Source Range to Data Array.
Dim LastRow As Long
Dim Data As Variant
With wb.Worksheets(sName).Range(sFirstCellAddress)
LastRow = .Worksheet.Cells(.Worksheet.Rows.Count, .Column).End(xlUp).Row
Data = .Resize(LastRow - .Row + 1, 3)
End With
' Write unique values from Data Array to Unique Dictionary.
Dim dict As Object: Set dict = CreateObject("Scripting.Dictionary")
dict.CompareMode = vbTextCompare
Dim arr(1 To 2) As Variant
Dim Key As Variant
Dim cArr As Variant
Dim r As Long
For r = 1 To UBound(Data, 1)
Key = Data(r, 1)
If Not IsError(Key) Then
If Not dict.Exists(Key) Then
dict.Add Key, arr
End If
If Data(r, 2) = 0 Then
cArr = dict(Key)
cArr(2) = cArr(2) + Data(r, 3)
dict(Key) = cArr
Else
cArr = dict(Key)
cArr(1) = cArr(1) + Data(r, 3)
dict(Key) = cArr
End If
End If
Next r
' Write values from Unique Dictionary to Result Array.
Dim rCount As Long: rCount = dict.Count + 1
Dim Result As Variant: ReDim Result(1 To rCount, 1 To 3)
Result(1, 1) = "Product"
Result(1, 2) = "Unit With DC Code"
Result(1, 3) = "Unit Without DC Code"
If rCount > 1 Then
r = 1
For Each Key In dict.Keys
r = r + 1
Result(r, 1) = Key
Result(r, 2) = CLng(dict(Key)(1))
Result(r, 3) = CLng(dict(Key)(2))
Next Key
End If
' Write values from Result Array to Destination Range.
With wb.Worksheets(dName).Range(dFirstCellAddress).Resize(, 3)
.Resize(rCount).Value = Result
' Delete below.
'.Resize(.Worksheet.Rows.Count - .Row - rCount + 1) _
.Offset(rCount).ClearContents
End With
End Sub

Answer 2

Here is an example of VBA code that should do the trick:
Sub SubWhyNotSUMIFS()
'Declarations.
Dim RngResult As Range
Dim RngTarget As Range
Dim RngSource As Range
Dim StrPreviousProduct As String
'Settings.
Set RngResult = Range("D1")
Set RngSource = Range("A2:C2")
Set RngSource = Range(RngSource, RngSource.End(xlDown))
'Creating space for the result.
RngResult.EntireColumn.Insert
RngResult.EntireColumn.Insert
RngResult.EntireColumn.Insert
'Reporting the headers of the result list.
Set RngResult = RngResult.Offset(0, -3)
RngResult.Value = "Product"
RngResult.Offset(0, 1) = "Unit with DC Code"
RngResult.Offset(0, 2) = "Unit Without DC Code"
'Covering each cell of the first column of RngSource.
For Each RngTarget In RngSource.Columns(1).Cells
'Checking if it's a different product.
If StrPreviousProduct <> RngTarget.Value Then
'Setting RngResult for a new row.
Set RngResult = RngResult.Offset(1, 0)
'Changing StrPreviousProduct.
StrPreviousProduct = RngTarget.Value
'Reporting the results.
RngResult.Value = RngTarget.Value
RngResult.Offset(0, 1).Value = Excel.WorksheetFunction.SumIfs(RngSource.Columns(3), RngSource.Columns(1), RngTarget.Value, RngSource.Columns(2), "<>0")
RngResult.Offset(0, 2).Value = Excel.WorksheetFunction.SumIfs(RngSource.Columns(3), RngSource.Columns(1), RngTarget.Value, RngSource.Columns(2), 0)
End If
Next
End Sub
You can reverse-engineer it. The lines you will be most interested into are:
RngResult.Offset(0, 1).Value = Excel.WorksheetFunction.SumIfs(RngSource.Columns(3), RngSource.Columns(1), RngTarget.Value, RngSource.Columns(2), "<>0")
RngResult.Offset(0, 2).Value = Excel.WorksheetFunction.SumIfs(RngSource.Columns(3), RngSource.Columns(1), RngTarget.Value, RngSource.Columns(2), 0)
Translated in actual formulas they are basically this:
=SUMIFS(C2:C7,A2:A7,D2,B2:B7,"<>0")
=SUMIFS(C2:C7,A2:A7,D2,B2:B7,"=0")
Assuming that your list spans from cell A1 (headers) to cell C7, that in cell D2 there is the unique product you are looking for. The code itself dynamically covers the list. Since it looks like your list is the only thing in their own columns, formulas like these:
=SUMIFS(C:C,A:A,D2,B:B,"<>0")
=SUMIFS(C:C,A:A,D2,B:B,"=0")
should still be effective.