Show/Hide Profile picture on each row based on Employee Name? - excel

Question

I have found a simple script that allows for hiding or showing a picture using the text in a shape. I like the functionality and would like to apply it to our list of employees. However, the way it is constructed right now would require me to add one macro for each person and that is not sustainable in the long run.
Is there a way to re-write this script so it sets the name of the picture based on the name of the employee that is located in column A? Then it would be really simple to just insert images and name them with the Employee name.
I also see that the button is mentioned in the code. So this also needs to be written more dynamically. Could I use a normal format control instead of a shape? (The button does not need to change the displayed text as in this script.)
I really would appreciate your help here. This would look really smooth and I think others would make good use of a VBA like this too.
Sub Macro1()
With ActiveSheet.Shapes("Rounded Rectangle 4").TextFrame2.TextRange.Characters
'Check if shape text is equal to "Hide"
If .Text = "Hide" Then
'Change shape text to "Show"
.Text = "Show"
'Hide shape
ActiveSheet.Shapes("Picture 1").Visible = False
'Continue here if shape is not equal to "Hide"
Else
'Change text to "Hide"
.Text = "Hide"
With ActiveSheet.Shapes("Rounded Rectangle 4")
'Move image named "Picture1" based to lower right corner of shape
ActiveSheet.Shapes("Picture 1").Left = .Left + .Width
ActiveSheet.Shapes("Picture 1").Top = .Top + .Height
'Show image
ActiveSheet.Shapes("Picture 1").Visible = True
End With
End If
End With
End Sub
Reference: https://www.get-digital-help.com/show-and-hide-a-picture-vba/
Example data:

Answer 1

First, I'd like to say that you would be much better off designing something like this in MS Access as opposed to Excel. There are lots of tutorials showing how to build exactly this with Access Forms. It would certainly be much easier to maintain.
That being said, your question was about doing this in Excel and I'll answer that with a simple implementation suggestion. Just bare in mind, it comes with what I would consider "messy" maintenance.
First, you have a bunch of shapes representing the show/hide buttons. Each of these shapes would need to have their own unique name (not important what the name is for this case) and each of them would need to be positioned inside the cell for the row they are meant to operate on (as shown in your example photo).
Next, each employee's photo would need to be named the same as your employee name (the value in column A in your example).
Lastly, you would need to set the "Assigned Macro" of each show/hide button to the same method (I've named my Button_Click()). That method implementation looks like this:
Sub Button_Click()
Dim clickedButton As Shape
Dim employeePhoto As Shape
Dim clickedButtonRow As Long
Dim employeeName As String
'// gets the row number in whcih the clicked button resides
Set clickedButton = ActiveSheet.Shapes(Application.Caller)
clickedButtonRow = clickedButton.TopLeftCell.Row
'// gets the employee name (column A in this case)
employeeName = ActiveSheet.Range("A" & clickedButtonRow).Value
Set employeePhoto = ActiveSheet.Shapes(employeeName)
With clickedButton
' //set the position of the employee photo
employeePhoto.Top = .Top + .Height
employeePhoto.Left = .Left + .Width
With .TextFrame.Characters
'// set the visibility of the associated employee picture based on the text state of the button
employeePhoto.Visible = .Text = "Show"
'// swap the label on the button
If ActiveSheet.Shapes(employeeName).Visible Then
.Text = "Hide"
Else
.Text = "Show"
End If
End With
End With
End Sub

Answer 2

When applying the solution from ArcherBird I discovered a need to add a button in the headline to hide/show all pictures. This provides for a better user experience.
I added this script to the sheet (not in a module) and connected it to a button.
In my document I have our company logo in the headline and I kept this visible at all times.
I hope somebody find this set-up useful! :-)
Dim c As Boolean
Sub Button4_Click()
c = c Xor True
ActiveSheet.Pictures.Visible = c
ActiveSheet.Pictures("CompanyLogo").Visible = True
End Sub