Use value in cell as range in macro - excel

Question

I want to use the value in cell as a dynamic way to change the range in my macro, more specifically when changing the colour of a cell.
Lets says CELL A1 hosts the desirable range data. The macro will always look at this cell. The text in A1 = 'B4' therefore I want this to be the selected cell to have a colour fill. This will be repeated quite a few times and the data will change, this is why i need it to be a dynamic macro not conditional formatting.
Below is the standard colour macro and is far as i can get, VBA noob sorry.
Sub Colour2()
'
' Colour2 Macro
'
'
Range("B4").Select
With Selection.Interior
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
.Color = 16731903
.TintAndShade = 0
.PatternTintAndShade = 0
End With
End Sub
Hope this makes sense and thanks for your understanding and help.
M

Answer 1

Highlight Range Supplied in a Cell
This is an automated solution. You run nothing. Just copy the codes in the appropriate modules.
As you change the range address in cell A1, the color is applied to the cells of the supplied range address and the range is selected.
Sheet object module e.g. Sheet1 (the name not in parentheses in the VBE Project Explorer)
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Const mAddress As String = "A1"
Const ColorValue As Long = 16731903
Dim mCell As Range: Set mCell = Range(mAddress)
If Not Intersect(mCell, Target) Is Nothing Then
On Error Resume Next
Dim rg As Range: Set rg = Range(mCell.Value)
On Error GoTo 0
If Not rg Is Nothing Then
Application.ScreenUpdating = False
' Removes the colors from all cells before applying the color.
applyColor rg, ColorValue, True
' Applies the color without removing the previously applied colors.
'applyColor rg, ColorValue
rg.Select
Application.ScreenUpdating = True
End If
End If
End Sub
Standard Module e.g. Module1 (optionally in the same sheet object module)
Sub applyColor( _
ByVal rg As Range, _
ByVal ColorValue As Long, _
Optional ByVal resetBeforeApply As Boolean = False)
If resetBeforeApply Then
rg.Worksheet.Cells.Interior.Color = xlNone
End If
With rg.Interior
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
.Color = ColorValue
.TintAndShade = 0
.PatternTintAndShade = 0
End With
End Sub
The standard module is preferred because it could then easily be used for other worksheets.