Excel VBA Replace the nth word in a string - excel

Question

my problem is the following:
I have two sets of strings. The "words" are separated with "+".
String 1: A25+F47+w41+r21+h65
String 2: 4+7+4+4+2
I have a textbox that identifies the word “w41” in string 1. It is the 3rd word in the string. I want to replace the 3rd word in string 2 and that would be the second “4”
What I have so far is:
I am using split function to split string 1 where there is a “+”:
Result=Split(String1, "+")
Then I use the UBound to find the position of w41 and the result is 3.
FindWordPosition = UBound(Result()) + 1
Now I want to split string 2 in the same way. But then I want to change the 3rd word in string 2 from “4” to “3” and then put it together again. The result would be:
String 2: 4+7+3+4+2
but I cannot figure out how to do it :(

Answer 1

One way is to use an ArrayList.
Not sure what you want to replace the matched item with. In the code below, it is being replaced with the sequence number, which matches what you describe, but may not be what you really want.
Option Explicit
Sub due()
Const str1 As String = "A25+F47+w41+r21+h65"
Const str2 As String = "4+7+4+4+2"
Const strMatch As String = "w41"
Dim AL As Object
Dim v, w, I As Long
Set AL = CreateObject("System.Collections.ArrayList")
'put str2 into arrayList
v = Split(str2, "+")
For Each w In v
AL.Add w
Next w
'Check str1 against matchStr to get positions and act on the item in AL at that position
v = Split(str1, "+")
For I = 0 To UBound(v)
'Note that arrayList index and "Split" array are zero-based
If strMatch = v(I) Then
AL.removeat I 'remove item in the same position as the position of the matched item
AL.Insert I, I + 1 'Insert new item at that same position. Could be anything. I chose I+1 to match what you wrote in your question.
End If
Next I
Debug.Print Join(AL.toarray, "+")
End Sub
=> 4+7+3+4+2

Answer 2

Replace With Index
This example should get you on your feet.
The Code
Option Explicit
' Results
' For w41:
' A25+F47+w41+r21+h65
' 4+7+3+4+1
' For h65:
' A25+F47+w41+r21+h65
' 4+7+4+4+5
Sub replaceWithIndex()
Const Criteria As String = "w41"
Const str1 As String = "A25+F47+w41+r21+h65"
Const str2 As String = "4+7+4+4+1"
Const Delimiter As String = "+"
Dim Split1() As String: Split1 = Split(str1, Delimiter)
Dim Split2() As String: Split2 = Split(str2, Delimiter)
' Note that an array obtained with 'Split' is always zero-based, while
' the result of 'Application.Match' is always one-based (hence '- 1').
Dim cMatch As Variant: cMatch = Application.Match(Criteria, Split1, 0)
If IsNumeric(cMatch) Then
Split2(cMatch - 1) = cMatch
Debug.Print "Source"
Debug.Print str1
Debug.Print str2
Debug.Print "Result"
Debug.Print Join(Split1, Delimiter)
Debug.Print Join(Split2, Delimiter)
End If
End Sub

Answer 3

You can simply loop the array and exit if found:
Public Sub BuildPositions()
Const Criteria As String = "w41"
Const String1 As String = "A25+F47+w41+r21+h65"
Const String2 As String = "4+7+4+4+2"
Const Delimiter As String = "+"
Dim Results() As String
Dim Positions() As String
Dim Index As Integer
Results = Split(String1, Delimiter)
Positions = Split(String2, Delimiter)
For Index = LBound(Results) To UBound(Results)
If Results(Index) = Criteria Then
Exit For
End If
Next
If Index <= UBound(Results) Then
' Result was located.
Positions(Index) = 1 + Index
End If
Debug.Print "Results:", String1
Debug.Print "Positions1:", String2
Debug.Print "Positions2:", Join(Positions, Delimiter)
End Sub
Output:
Results: A25+F47+w41+r21+h65
Positions1: 4+7+4+4+2
Positions2: 4+7+3+4+2