How to add DUE DATE, counting start from table INVOICE DATE in Microsoft Office Excel ?
I don't know how to using this formula, but I got some hints :
if an invoices start date between 2-15 per months, due date automatically filled date 15 next month
Examples:
INVOICE DATE | DUE DATE format (D-M-Y)---------------------------------
11/08/2019 | 15/09/2019
15/08/2019 | 15/09/2019
02/09/2019 | 15/10/2019
if an invoices start date between 16-31 per months and date 1st next month, due date automatically filled date 1 every 2 next months
Examples:
INVOICE DATE | DUE DATE format (D-M-Y)---------------------------------
21/08/2019 | 01/10/2019
16/08/2019 | 01/10/2019
01/09/2019 | 01/10/2019
01/12/2019 | 01/01/2020
30/12/2019 | 01/02/2020
what should I do, prefer on table A or table B ? for easy to use ?
fixed image here
or you can download it here -> Google Drive(Fixed)
Try this one (the invoice date is in cell A1 here):
=IF(AND(DAY(A1)<16,DAY(A1)>1),DATE(YEAR(EOMONTH(A1,1)),MONTH(EOMONTH(A1,1)),15),DATE(YEAR(EOMONTH(A1,2)),MONTH(EOMONTH(A1,2)),1))
Try below formula. You have to format the resulting cell as date format.
=IF(AND(DAY(A2)>=2,DAY(A2)<=15),DATE(YEAR(A2),MONTH(A2+1),15),DATE(YEAR(A2),MONTH(A2)+2,1))
Related
I am currently trying to use a excel formula to estimate how long a record has been open based off of two fields and today's date. I however want to have the formula to be blank if the "Closed Date" is not populated. I haven't had success with getting this result.
Example in Excel:
| | A - Open Date | B - Closed Date |
|---|-----------------|-----------------|
| 1 | 02 January 2019 | 04 January 2019 |
| 2 | 02 January 2019 | |
| 3 | | |
I currently am using the following formula for each pertaining row;
=IF(B1>0, B1-A1,TODAY()-A1)
=IF(B2>0, B2-A2,TODAY()-A2)
=IF(B3>0, B3-A3,TODAY()-A3)
For the first row I will get 2 which is correct. The second row will also have 2 but will go up each day which is also correct. The third row will have a large number like 43559 which is due to there being no open date in A3. Any assistance would be appreciated. Thank you.
I'll add this as an answer as I think you mean:
If "Open Date" is not populated show a blank
If "Closed Date" is not populated use todays date.
=IF(A1="","",IF(B1="",TODAY(),B1)-A1)
Maybe: =IF(B1="","",B1-A1) ??
I'm trying to put together a calendar of regular payments which will have a date begun, day the money is paid and the date cancelled (if there is one), however I'm struggling with setting up my SUMIFS function. I've set up an example here.
What I'm trying to do is add the paid value on the day the payment is made, if the date started is less than the date, and only if the date cancelled is empty or the date is before the date cancelled.
List of payments:
A B C
1 Payment | Begun | Cancelled
---------+------------+------------
2 £5.00 | 01/01/2016 |
3 £9.00 | 04/01/2016 | 01/02/2016
Calendar (that I'd expect):
E F
1 Date | Payment
----------+---------
2 01/01/16 | £5.00
3 02/01/16 | £0.00
4 03/01/16 | £0.00
5 04/01/16 | £9.00
...
33 01/02/16 | £5.00
34 02/02/16 | £0.00
35 03/02/16 | £0.00
36 04/02/16 | £0.00
So in this example: £5 should be added on 01/01/16 and 01/02/16, while £9 should be added on 04/01/16 only.
So far in the F column I have:
=SUMIFS($A$2:$A$3, DAY($B$2:$B$3), "="&DAY(E2), $B$2:$B$3, "<="&E2, $C$2:$C$3, ">="&E2)
This Array formula in F2 should do what you want:
=SUM(IF((DAY($B$2:$B$3)=DAY(E2))*(E2>=$B$2:$B$3)*(E2<=$C$2:$C$3),$A$2:$A$3))+SUM(IF((DAY($B$2:$B$3)=DAY(E2))*(E2>=$B$2:$B$3)*(""=$C$2:$C$3),$A$2:$A$3))
It is an Array formula and must be confirmed with Ctrl-Shift-Enter. Then copied down.
The 'OR' in Array formulas must use a +. If all you had were AND the * would work.
I assume you are going to be adding dates to columns A:C, you can change all the small absolute ranges to the desired ranges and it will work for multiples.
Do forgive our backwards dates.
you should just ADD the results of two separate SUMIF()'s in your case:
=SUMIFS($A$2:$A$3, DAY(B$2:B$3), "="&DAY(E2), $B$2:$B$3, "<="&E2, $C$2:$C$3,">="&E2)
+
SUMIFS($A$2:$A$3, DAY(B$2:B$3), "="&DAY(E2), $B$2:$B$3, "<="&E2, ISBLANK($C$2:$C$3),TRUE)
Confirm with Ctrl+Shift+enter
Hopefully somebody can help me figure out a better way to create what I need in a pivotTable. I have a table structured as follows:
Date | ID# | Revenue
---------------------------------------
1/1/14 | 123 | $200.00
1/1/14 | 234 | $99.00
1/5/14 | 455 | $100.00
1/31/14 | 5666 | $50.00
2/4/14 | 2454 | $500.00
...
...
...
12/4/14 | 88484 | $3000.00
Unfortunately, when I create a pivotTable off of this information, and then try to process the data all the way into chart data, it gives me only dated entries when there is an actual entry.
What I need is to not only create a table that shows dates that had $0.00 revenue, but also a chart that displays all 365 days, without manually going back day by day (as there are 1000+ rows) to enter a day that has a $0.00 revenue.
Any ideas?
One approach would be to put the days of the year into a spare column, say D, by starting with 1/1/14 in D2, pulling down with the right mouse button and choosing 'Fill Days'.
Then put a formula into column E starting in E2 like
=SUMIF(A:A,D2,C:C)
to put in the total revenue for each day in column C based on all matching days in column A.
that's assuming that what you want is the total revenue for each day of the year whether or not it's zero.
Say I have a spreadsheet with the following, and for convenience say all of this starts from cell A1.
---------------------------------------
| Date | Item | Account |
---------------------------------------
| 01/09/2011 | Testing 1 | USD |
| 03/09/2011 | Testing 2 | USD |
| 11/09/2011 | Testing 3 | USD |
| 20/10/2011 | Testing 4 | JD |
| 22/10/2011 | Testing 5 | JD |
| 25/10/2011 | Testing 6 | USD |
| 03/11/2011 | Testing 7 | USD |
| 05/11/2011 | Testing 8 | JD |
---------------------------------------
Now, I want to run a report for a month, starting on 1/10/2011 and ending on 31/10/2011. I need to find the first row on or after the starting date, and then get every subsequent row until the end date. If I can figure out how to get the row reference for the first and end dates, then I can figure out the rows in between (obviously!).
I have only been able do these sorts of matches on exact matches ie. no idea how to do 'greater/less than' matches.
How would I go about matching on both the date and the account columns?
Needless to say, this needs to be in a formula.
=match(date(2011,10,1),a2:a9,1)+1
=match(date(2011,10,31),a2:a9,1)
First formula shows row for the first record for October, second formula for the last day. Data must be sorted in ascending order.
Use the following Array Formula for finding the Row containing the earliest date, which is equal to or greater than the date mentioned in cell C1 (in your case this is 1 October).
=MATCH(MIN(IF($A$1:$A$30>=C1,1,9999)*$A$1:$A$30),$A$1:$A$30,0)
Date list is in cells A1 to A30. Change the references as required.
Data need not be sorted in ascending or descending order.
Use the following Array Formula for finding the Row containing the latest date which is equal to or less than the date mentioned in cell D1 (in your case this is 31 October). Data need not be sorted in ascending or descending order.
=MATCH(MAX(IF($A$1:$A$30<=D1,1,0)*$A$1:$A$30),$A$1:$A$30,0)
If you want the earliest and latest dates, use the following Array Formulas.
=MIN(IF($A$1:$A$30>=C1,1,9999)*$A$1:$A$30)
=MAX(IF($A$1:$A$30<=D1,1,0)*$A$1:$A$30)
All the formulas used above are Array Formulas. To enter an array formula, use Control+Shift+Enter instead of Enter.
Vijaykumar Shetye, Goa, India
I would recommend using a pivot table for this. Look at the second link on in the "Excel Templates - Pivot Table" section on this page on the Contextures site.
I'm trying to figure out how to auto generate/populate a column in excel based on the number of hours filled in another column:
Start date: 04-08-2011
Hours in one day: 8
Issues Hours Date
part 1 | 2 | 04-08-2011
part 2 | 6 | 04-08-2011
part 3 | 2 | 05-08-2011
part 4 | 2 | 05-08-2011
part 5 | 8 | 06-08-2011
part 6 | 2 | 06-08-2011
So when i add issue 'part 1' the date starts # the start date, when i add hours or 'parts' it continues to use the start days until it reaches 8 hours and continues to the next day.
Also when im adding a row between the existing rows it automatically recalculates the dates.
Anny ideas where to start? Tnx
If I understand what you are asking correctly, and assuming start date is in Cell B1, and hours in 1 day B2
And data header in A4:C4, with data below
Then put the formula '=$B$1+INT(SUM($B$5:B5)/$B$2-0.1)' in C5
Copy C5 down and it should generate the date automatically
The '-0.1' is to account for exactly 8 hrs being allowed in 1 day