Run-time error '-2147417848 (80010108)': Method 'Insert' of object 'Range' failed - excel

Question

I am attempting to track changes in our financial models. The aim is to identify who is back solving.
I have written code that executes until I switch from one sheet to only one other specific sheet.
Sub tracker()
Dim Cell As Range
For Each Cell In Sheets("Input check IC").Range("AI2:AI128")
If Cell.Value <> 0 Then
With Sheets("Copy IC")
Sheets("Change tracker").Range("C10000").End(xlUp).Offset(1, 0).Resize(, 33).Value = .Range(.Cells(Cell.Row, "A"), .Cells(Cell.Row, "AG")).Value
End With
End If
Next
For Each Cell In Sheets("Input check IC").Range("AI2:AI128")
If Cell.Value <> 0 Then
With Sheets("Live IC")
Sheets("Change tracker").Range("C10000").End(xlUp).Offset(1, 0).Resize(, 33).Value = .Range(.Cells(Cell.Row, "A"), .Cells(Cell.Row, "AG")).Value
End With
End If
Next
'Live IC
Sheets("Live IC").Range("B2:AG128").Copy
Sheets("Copy IC").Range("B2").PasteSpecial Paste:=xlPasteValues
Application.CutCopyMode = False
End Sub
I have a duplicate code for "RC" where: IC = investment case ; RC = reference case. RC is called from tracker 2 in a separate module.
The code executes perfectly when I go to any sheet in the workbook, other than RC (from IC)/ IC (from RC). I might add the code is called when the sheet is deactivated. I feel the code is stuck in a loop when I deactivate/active IC/RC in succession.
It runs until the following error
Run-time error '-2147417848 (80010108)': Method 'Insert' of object 'Range' failed'

Answer 1

Copy Ranges
Assuming that all worksheets are in the workbook containing this code.
Note that arrays will handle this more efficiently. Consider it as a lesson in ranges.
Not tested.
The Code
Option Explicit
Sub tracker()
Dim wb As Workbook: Set wb = ThisWorkbook
Dim cws As Worksheet: Set cws = wb.Worksheets("Input check IC")
Dim dst As Worksheet: Set dst = wb.Worksheets("Change tracker")
Dim sws As Variant: ReDim sws(1 To 2)
Set sws(1) = wb.Worksheets("Copy IC")
Set sws(2) = wb.Worksheets("Live IC")
Dim crg As Range: Set crg = cws.Range("AI2:AI128")
Dim drg As Range
Set drg = dst.Cells(dst.Rows.Count, "C").End(xlUp) _
.Resize(, 33).Offset(1, 0)
Dim srg As Range
Dim n As Long
Dim i As Long
For n = 1 To 2
Set srg = sws(n).Range("A2").Resize(crg.Rows.Count, 33)
For i = 1 To crg.Cells.Count
If crg.Cells(i).Value <> 0 Then
drg.Value = srg.Rows(i).Value
Set drg = drg.Offset(1)
End If
Next i
Next n
'Live IC
sws(1).Range("B2:AG128").Value = sws(2).Range("B2:AG128").Value
End Sub