received runtime error 13 will utilizing instring function - excel

Question

when i import a file the second time, the data from the first time is not being deleted. Thus, once i import the second file, the second file data starts at the column beside the first data. My code below, after the import part is what i tryna resolve this issue
Sub ImportCMOSLog(Path As String, filename As String)
'Sheets.Add After:=Sheets(Sheets.Count)
Sheets("Data").Select
On Error Resume Next
'ActiveSheet.Name = filename
Range("A1").FormulaR1C1 = filename
Range("A2").Select
With ActiveSheet.QueryTables.Add(Connection:= _
"TEXT;" & Path & filename, Destination:=Range("$A$1"))
.Name = filename 'change activesheet to sheets("Data")
.FieldNames = True
.RowNumbers = False
.FillAdjacentFormulas = False
.PreserveFormatting = True
.RefreshOnFileOpen = False
.RefreshStyle = xlInsertDeleteCells
.SavePassword = False
.SaveData = False
.AdjustColumnWidth = False
.RefreshPeriod = 0
.TextFilePromptOnRefresh = False
.TextFilePlatform = xlWindows
.TextFileStartRow = 1
.TextFileParseType = xlDelimited
.TextFileTextQualifier = xlTextQualifierDoubleQuote
.TextFileConsecutiveDelimiter = False
.TextFileOtherDelimiter = "|"
.TextFileDecimalSeparator = "."
.TextFileThousandsSeparator = " "
.Refresh BackgroundQuery:=False
End With
End Sub
Dim strSearch As String
strSearch = "Time/min"
Dim x As String
Dim sheet As String
Dim myrange As String
sheet = "Data"
myrange = "$A$1:$BC$1"
Set x = Worksheets("Data").Range("$A$1:$BC$1") [object required error over here]
For Each Cell In x
If InStr(x.Value, strSearch) > 0 Then [runtime error received over here]
lastrow = ActiveCell.SpecialCells(xlLastCell).Row
Columns("B:B").Select
Selection.Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove
Range("B1").Select
ActiveCell.FormulaR1C1 = "Time/min"
Range(Cells(2, 2), Cells(lastrow, 2)).Select
Selection.FormulaR1C1 = "=(RC[-1]-R3C1)*24*60"
Selection.NumberFormat = "General"
Else
Sheets("Data").Cells.Clear
End If
Next Cell

Answer 1

I think you are making it complex then required (I could be wrong about this) but what you are actually trying to do is
Clear old data
Insert new data which had headers as Date, Y1 and Y2
Insert a column in B
Give it a header Time/min so that new headers are Date, Time/min, Y1 and Y2
Insert the formula in column B
If my understanding is correct, then try this (UNTESTED). Let me know if you get any errors.
Option Explicit
Sub ImportCMOSLog(Path As String, filename As String)
Dim ws As Worksheet
Dim lRow As Long
'~~> Change this to the relevant sheet
Set ws = ThisWorkbook.Sheets("Data")
With ws
.Cells.Clear
With .QueryTables.Add(Connection:= _
"TEXT;" & Path & filename, Destination:=.Range("$A$1"))
.Name = filename
.FieldNames = True
.RowNumbers = False
.FillAdjacentFormulas = False
.PreserveFormatting = True
.RefreshOnFileOpen = False
.RefreshStyle = xlInsertDeleteCells
.SavePassword = False
.SaveData = False
.AdjustColumnWidth = False
.RefreshPeriod = 0
.TextFilePromptOnRefresh = False
.TextFilePlatform = xlWindows
.TextFileStartRow = 1
.TextFileParseType = xlDelimited
.TextFileTextQualifier = xlTextQualifierDoubleQuote
.TextFileConsecutiveDelimiter = False
.TextFileOtherDelimiter = "|"
.TextFileDecimalSeparator = "."
.TextFileThousandsSeparator = " "
.Refresh BackgroundQuery:=False
End With
.Columns(2).Insert Shift:=xlToRight
.Range("B1").Value = "Time/min"
lRow = .Range("A" & .Rows.Count).End(xlUp).Row
.Range("B2:B" & lRow).FormulaR1C1 = "=(RC[-1]-R3C1)*24*60"
End With
End Sub