Scrape an innertext from Wikipedia's infobox - excel

Question

Doing a project that requires using a command button should extract some info from a webpage.
I chose to have 'Confirmed Cases' from Wikipedia's infobox of the COVID-19 pandemic, I can't seem to write the correct "getElementsBy.." to have the info extracted.
Private Sub AccesswebsitePAN_Click()
WB_PAN.Navigate ("https://en.wikipedia.org/wiki/COVID-19_pandemic")
End Sub
Private Sub GetinfoPAN_Click()
Cells(2, 1).Value = WB_PAN.Document.getElementsById("mw-content-text").getElementsByClassName("mw-parser-output").getElementsByTagName("table").getElementsByTagName("tbody").getElementsByTagName("tr")(12).getElementsByTagName("td")(0).Innertext
End Sub
Private Sub WB_PAN_StatusTextChange(ByVal Text As String)
End Sub

Answer 1

As ID is a unique locator, you can try using the same within your script to fetch the result.
Option Explicit
Sub GetCaseCount()
Const Url$ = "https://en.wikipedia.org/wiki/COVID-19_pandemic"
Dim Http As Object, elem As Object, S$
With CreateObject("MSXML2.XMLHTTP")
.Open "GET", Url, False
.setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 6.1) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/85.0.4183.121 Safari/537.36"
.send
S = .responseText
End With
With CreateObject("htmlfile")
.body.innerHTML = S
Set elem = .getElementById("cite_ref-JHU_ticker_5-0")
Debug.Print elem.ParentNode.innerText
End With
End Sub
The script should work without adding any reference to the library.

Answer 2

You have neglected at several stages to index into collections returned by getElementsBy methods. Also, it is getElementById. I might go for a more readable shorter path that selects the table by its class (using querySelector) then use the .rows method.
Your way:
Debug.Print WB_PAN.Document.getElementById("mw-content-text").getElementsByClassName("mw-parser-output")(0).getElementsByTagName("table")(0).getElementsByTagName("tbody")(0).getElementsByTagName("tr")(18).getElementsByTagName("td")(0).Innertext
Alternative:
Option Explicit
Public Sub CovidCases()
Dim ie As SHDocVw.InternetExplorer
Set ie = New SHDocVw.InternetExplorer
With ie
.Visible = True
.Navigate2 "https://en.wikipedia.org/wiki/COVID-19_pandemic"
While .Busy Or .ReadyState <> READYSTATE_COMPLETE: DoEvents: Wend
Debug.Print .Document.querySelector(".infobox").Rows(12).innertext
Debug.Print .Document.querySelector(".infobox").Rows(12).firstchild.nextsibling.innertext
.Quit
End With
End Sub
Slightly cleaner is to clear out, using an approach from user4596341, the node html that adds the lagging [4] reference before taking your cases, such that you have a more readable path
Option Explicit
Public Sub CovidCases()
Dim ie As SHDocVw.InternetExplorer
Set ie = New SHDocVw.InternetExplorer
With ie
.Visible = True
.Navigate2 "https://en.wikipedia.org/wiki/COVID-19_pandemic"
While .Busy Or .ReadyState <> READYSTATE_COMPLETE: DoEvents: Wend
.Document.querySelector(".infobox tr:nth-of-type(13) sup").innerHTML = vbNullString
Debug.Print .Document.querySelector(".infobox").Rows(12).Cells(1).innertext
.Quit
End With
End Sub
Seeing #Sim's answer reminded me you can walk back up the DOM to get just the case count which is even cleaner:
Option Explicit
Public Sub CovidCases()
Dim ie As SHDocVw.InternetExplorer
Set ie = New SHDocVw.InternetExplorer
With ie
.Visible = True
.Navigate2 "https://en.wikipedia.org/wiki/COVID-19_pandemic"
While .Busy Or .ReadyState <> READYSTATE_COMPLETE: DoEvents: Wend
Debug.Print .Document.querySelector(".infobox tr:nth-of-type(13) sup").PreviousSibling.NodeValue
.Quit
End With
End Sub