Inserting information from a cell into code - excel

Question

I have been working on a spreadsheet where I want a VBA code to open a document, now this document could be either a word or excel document, but I want the code to use the information from a cell.
Function FnPrint()
Dim objWord
Dim objDoc
Set objWord = CreateObject("Word.Application")
Set objDoc = objWord.Documents.Open("Y:\Master Documents\Sheet & Cut\W19-316 Allergen cleandown S&C line.docx")
objWord.Visible = True
objDoc.PrintOut
objWord.Quit
End Function
That is the code that I have, Now where it says "Y:\Master Documents\Sheet & Cut\W19-316 Allergen cleandown S&C line.docx", I want that to actually change depending on a certain cell, which you can see in the above image. This is because that cell changes depending on the variables entered in the other boxes.
Any Ideas?

Answer 1

..to open a document, now this document could be either a word or excel document
Logic:
Check the file extension of the file path in the cell and then decide whether you want to open Excel or Word.
Code (Untested):
Option Explicit
Sub Sample()
Dim rngDocInfo As Range
Dim objApp As Object, objDoc As Object
Dim myPath As String
'~~> Change this to relevant sheet and cell which has the path
Set rngDocInfo = Sheet1.Range("O18")
myPath = UCase(rngDocInfo.Value2)
If Len(Dir(myPath)) = 0 Then
MsgBox "Invalid filename. File does not exist"
Exit Sub
End If
'~~> Get file extension and check if it is an Excel document
If Right(myPath, Len(myPath) - InStrRev(myPath, ".")) Like "XLS*" Then
Set objApp = CreateObject("Excel.Application")
Set objDoc = objApp.Workbooks.Open(rngDocInfo.Value2)
objApp.Visible = True
'
' Rest of the code
'
'~~> Get file extension and check if it is a Word document
ElseIf Right(myPath, Len(myPath) - InStrRev(myPath, ".")) Like "DOC*" Then
Set objApp = CreateObject("Word.Application")
Set objDoc = objApp.Documents.Open(rngDocInfo.Value2)
objApp.Visible = True
'
' Rest of the code
'
Else
MsgBox "Unknown Document type"
End If
End Sub
Note: I am not handling Text/Csv Files in the above code. If you can have those file types then amend the above code accordingly.