How can I delete pdf files when sums to zero - excel

Question

I'm trying to see if there is a way to delete a pdf file when the row balances to zero. I tried to follow this but I could not get it to work for me, any help pointing me in the right direction would be greatly appreciated.
Goals
Delete pdf file if Column N5 balances to zero if exists, pdf is named after RGN in A5 usually
Loop through all the rows and until it reaches the end
Bonus would be to account for wildcard naming since sometimes the pdf could be RGN_649610.pdf
Example 649610.pdf should be deleted when N5 balances to 0 as shown in the image.
C:.
│ TES_123.xlsx
│
└───Scanned
├───DIR1
│ 649610.pdf
│ 649615.pdf
│
└───DIR2
649612.pdf
649617.pdf
Excel image
Code I tried
Sub delete_INACTIVE_files()
Const path = "C:\Users\bmh\Desktop\TES 123\"
Dim r As Range
Set r = Cells(5, 14)
Do Until r = ""
If UCase(r.Value) = "0" Then
If Dir(path & "Scanned" & "\DIR1" & "\" & r.Offset(0, -13) & ".pdf") <> "" Then
Kill path & "Scanned" & "\DIR1" & "\" & r.Offset(0, -13) & ".pdf"
End If
End If
Set r = r.Offset(5, 0)
Loop
End Sub

Answer 1

Try this:
Sub delete_INACTIVE_files()
Const PATH = "C:\Users\bmh\Desktop\TES 123\Scanned\"
Dim r As Range, ws As Worksheet, id, n, f, files As Collection, fName
Set files = GetMatches(PATH, "*.pdf") 'find all files in the folder/subfolders
Set ws = ActiveSheet
Set r = ws.Cells(5, 14)
Do While Len(r.Value) > 0
If r.Value = 0 Then
id = ws.Cells(r.Row, "A").Value 'get the Region
'find any matching files and delete them
For n = files.Count To 1 Step -1
Set f = files(n)
fName = UCase(f.Name)
If fName = id & ".PDF" Or _
fName = "RGN_" & id & ".PDF" Then
f.Delete 'delete the file
files.Remove n 'remove from the collection
End If
Next n
End If
Set r = r.Offset(1, 0) 'next row
Loop
End Sub
'Return a collection of file objects given a starting folder and a file pattern
' e.g. "*.txt"
'Pass False for last parameter if don't want to check subfolders
Function GetMatches(startFolder As String, filePattern As String, _
Optional subFolders As Boolean = True) As Collection
Dim fso, fldr, f, subFldr
Dim colFiles As New Collection
Dim colSub As New Collection
Set fso = CreateObject("scripting.filesystemobject")
colSub.Add startFolder
Do While colSub.Count > 0
Set fldr = fso.getfolder(colSub(1))
colSub.Remove 1
For Each f In fldr.files
If UCase(f.Name) Like UCase(filePattern) Then colFiles.Add f
Next f
If subFolders Then
For Each subFldr In fldr.subFolders
colSub.Add subFldr.PATH
Next subFldr
End If
Loop
Set GetMatches = colFiles
End Function