Determine highest value of two numbers - excel

Question

I have a table with five columns and two rows.
Name
Surname
Sum of grades
Number of grades
Average
John
Smith
30
2
15
Jack
Decker
15
2
7.5
I want a message box saying "The best student is (Name & Surname)" based on average.
I tried several things such as declaring maximum of the E range and then getting row number etc.
I've checked the Find and Indirect function.
Sub BestStudent()
Dim Maximum As Integer
Dim Rng As Range
Dim rownumber As Integer
rownumber = ActiveCell.Row
Set Rng = Range("E1:E2")
Maximum = WorksheetFunction.Max(Rng)
If ActiveCell.Value = Maximum Then
MsgBox ("The best student is..)
End Sub

Answer 1

Using a sort to get the highest value:
Dim lr As Long
With Sheet1 'Change to whatever your sheet's code name is
lr = .Cells(.Rows.Count, 1).End(xlUp).Row
.Range("A2:E" & lr).Sort Range("E2"), xlDescending
MsgBox "The best student is " & .Cells(2, 1).Value & " " & .Cells(2, 2).Value
End With
Using Max and Find:
Dim maximum As Double
Dim findrng As Range
Dim rng As Range
Dim lr As Long
With Sheet1
lr = .Cells(.Rows.Count, 1).End(xlUp).Row
Set rng = .Range("E2:E" & lr)
maximum = Application.WorksheetFunction.Max(rng)
Set findrng = rng.Find(maximum, , xlValues, xlWhole)
If Not findrng Is Nothing Then
MsgBox "The best student is " & .Cells(findrng.Row, 1).Value & " " & .Cells(findrng.Row, 2).Value
Else
MsgBox "Something went wrong, Value not found."
End If
End With
Using a loop:
Dim lr As Long
Dim i As Long
Dim maximum As Double
Dim rownum As Long
With Sheet1
lr = .Cells(.Rows.Count, 1).End(xlUp).Row
For i = 2 To lr
If maximum < .Cells(i, 5).Value Then
maximum = .Cells(i, 5).Value
rownum = i
End If
Next i
MsgBox "The best student is " & .Cells(rownum, 1).Value & " " & .Cells(rownum, 2).Value
End With

Answer 2

You can do this :
Dim Maximum As Double
Dim i, lastline As Integer
Dim names As String
names = ""
Range("E2").Select
' get maximum
Maximum = WorksheetFunction.Max(Range(Selection, Selection.End(xlDown)))
'get last line
lastline = Range(Selection, Selection.End(xlDown)).Rows.Count
For i = 2 To (lastline + 1)
If ThisWorkbook.Sheets("Feuil1").Cells(i, 5).Value = Maximum Then
If names = "" Then
names = ThisWorkbook.Sheets("Feuil1").Cells(i, 1).Value & " " & ThisWorkbook.Sheets("Feuil1").Cells(i, 2).Value
Else
names = names & " and " & ThisWorkbook.Sheets("Feuil1").Cells(i, 1).Value & " " & ThisWorkbook.Sheets("Feuil1").Cells(i, 2).Value
End If
End If
Next i
MsgBox "The best student is (are) : " & names