VBA Excel: message box and non english words [duplicate] - excel

Question

This question already has answers here:
How do I display a messagebox with unicode characters in VBA?
(2 answers)
Unicode string literals in VBA
(3 answers)
Closed 2 years ago.
Has anyone a workaround to show Arabic in a message box. I even changed the font to Arial (Arabic) in VBA setting and I cant write Arabic in the code but when it runs its shows garbage words in the message box.
Below is a sample code even though it's showing as CaCaCa below but in my VBA it's a proper Arabic word.
Private Sub cmdDelete_Click()
Dim iRow As Long
If Selected_List = 0 Then
Font.Name = "Arial Unicode MS"
MsgBox "ÇáÇãÇä No row is selected. ", vbOKOnly + vbInformation, "Delete"
Exit Sub
End If

Answer 1

An approach based on #Tarik 's link to MsgBox with Unicode characters:
VBA7 Declaration of API function MessageBoxW()
Option Explicit ' Declaration head of code module
Private Declare PtrSafe Function MessageBoxW Lib "User32" ( _
ByVal hWnd As LongPtr, _
ByVal lpText As LongPtr, _
ByVal lpCaption As LongPtr, _
ByVal uType As Long) _
As Long
Help function MsgBoxW()
'Site: https://stackoverflow.com/questions/55210315/how-do-i-display-a-messagebox-with-unicode-characters-in-vba
Function MsgBoxW( _
Prompt As String, _
Optional Buttons As VbMsgBoxStyle = vbOKOnly + vbInformation, _
Optional Title As String = " Delete") _
As VbMsgBoxResult
Title = WorksheetFunction.Unichar(&H1F4BC) & Title
MsgBoxW = MessageBoxW(Application.hWnd, StrPtr(Prompt), StrPtr(Title), Buttons)
End Function
Note that Access would need a Application.hWndAccessApp argument to get the corresponding window handle.
Example call
Sub ExampleCall()
Dim s As String
s = WorksheetFunction.Unichar(&H2776) & " " & getArabic() & vbNewLine & vbNewLine & _
WorksheetFunction.Unichar(&H2777) & " No Rows selected. "
MsgBoxW s
End Sub
Hardcoding test function getArabic()
As I don't know the Arabic language, the following function only tries to simulate a correct phrase I got via a translation site by joining single unicode values of a hardcoded array to a string like e.g. ; so I beg your pardon for any mistranslation :-)
There are numerous sites where you can get the hexadecimal or decimal code values immediately.
It would be possible as well to insert your original string into an Excel sheet cell and analyze the corresponding character values one by one (e.g. via formula =UNICODE(MID($A2,1,1)) etc.)
Function getArabic()
'Note: uses decimal values here (e.g. decimal 1604 equals hexadecimal &H644)
Dim arr: arr = Array(1604, 1605, 32, 1610, 1578, 1605, 32, 1578, 1581, 1583, 1610, 1583, 32, 1589, 1601, 46)
Dim a, s As String
For Each a In arr
s = s & WorksheetFunction.Unichar(a)
Next a
getArabic = s
End Function

Answer 2

The computer you are using should have the default code page to Windows 1256. That way, it interprets any extended ASCII character (above 127) as Arabic. The alternative (preferred option) is to ensure you use UTF-8.
See How do I display a messagebox with unicode characters in VBA?