Override Spock mock with method instead of value - groovy

Question

I know that using Spock I can create a Mock and set a return value on a method e.g.
idpClient.adminCreateUser(_) >> [
user: new UserType()
]
How can I set a method on the Mock so I can customise the value that gets returned? I want to do something like:
idpClient.metaClass.adminCreateUser = { AdminCreateUserRequest adminCreateUserRequest ->
UserType user = new UserType()
user.setUsername(adminCreateUserRequest.getUsername())
AdminCreateUserResult result = new AdminCreateUserResult()
result.setUser(user)
return result
}
Though obviously the above does not work (it returns null). I've looked at the documentation but all I've found is how to return a fixed value (see above).

Answer 1

Maybe you ought to read the Spock manual. There is a section on computing return values. There is no need to use meta classes, the Spock DSL provides syntactical means for stubbing.
I made up this little example for you as an MCVE:
package de.scrum_master.stackoverflow.q64961803;
class UserType {
private String userName;
public void setUserName(String userName) { this.userName = userName; }
public String getUserName() { return userName; }
}
package de.scrum_master.stackoverflow.q64961803;
public class AdminCreateUserResult {
private UserType user;
public void setUser(UserType user) { this.user = user; }
public UserType getUser() { return user; }
}
package de.scrum_master.stackoverflow.q64961803;
public class AdminCreateUserRequest {
private String userName;
public AdminCreateUserRequest(String userName) { this.userName = userName; }
public String getUserName() { return userName; }
}
package de.scrum_master.stackoverflow.q64961803;
public class IDPClient {
public AdminCreateUserResult adminCreateUser(AdminCreateUserRequest adminCreateUserRequest) {
AdminCreateUserResult userResult = new AdminCreateUserResult();
UserType userType = new UserType();
userType.setUserName("real user");
userResult.setUser(userType);
return userResult;
}
}
Shen the corresponding Spock specification would look like this:
package de.scrum_master.stackoverflow.q64961803
import spock.lang.Specification
class IDPClientTest extends Specification {
def test() {
given: "mock IDPClient with stubbed method"
IDPClient idpClient = Mock() {
adminCreateUser(_) >> { AdminCreateUserRequest adminCreateUserRequest ->
UserType user = new UserType()
user.setUserName(adminCreateUserRequest.getUserName())
AdminCreateUserResult result = new AdminCreateUserResult()
result.setUser(user)
result
}
}
def request = new AdminCreateUserRequest("test user")
expect: "real IDPClient behaves normally"
new IDPClient().adminCreateUser(request).user.userName == "real user"
and: "mock IDPClient displays stub behaviour"
idpClient.adminCreateUser(request).user.userName == "test user"
}
}