Creating an automatic generated worksheet menu - excel

Question

I am struggling with fine tuning my VBA for an automatic generated worksheet menu. So far I have the following;
Dim objSheet As Worksheet
Worksheets("General Information").Activate
Range("W14").Select
For Each objSheet In ActiveWorkbook.Worksheets
If ActiveSheet.Name <> objSheet.Name Then
ActiveCell.Hyperlinks.Add Anchor:=Selection, Address:="", SubAddress:="'" & objSheet.Name & "'" & "!A1", TextToDisplay:=objSheet.Name
ActiveCell.Offset(1, 0).Select
ActiveCell.EntireColumn.AutoFit
End If
Next objSheet
This works perfectly. However, I would like to have a fixed starting point as the first few sheets are always the same.
In other words I need this to work as of the 12th worksheet onwards.
Can you please help me out with this addition, thanks

Answer 1

Try like this:
Const intSheetStart As Integer = 12
Dim intCount As Integer
Dim objSheet As Worksheet
Worksheets("General Information").Activate
Range("W14").Select
intCount = 0
For Each objSheet In ActiveWorkbook.Worksheets
intCount = intCount + 1
If intSheetStart <= intCount Then
If ActiveSheet.Name <> objSheet.Name Then
ActiveCell.Hyperlinks.Add Anchor:=Selection, Address:="", SubAddress:="'" & objSheet.Name & "'" & "!A1", TextToDisplay:=objSheet.Name
ActiveCell.Offset(1, 0).Select
ActiveCell.EntireColumn.AutoFit
End If
End If
Next objSheet
This change sets the starting point in a constant, then counts the sheets and only runs the rest of the code if the current sheet is the starting point or after.

Answer 2

A different way of controlling it, is using another kind of loop, and set a starting point in the code.
For i = 12 To ActiveWorkbook.Worksheets.Count
ActiveCell.Hyperlinks.Add Anchor:=Selection, Address:="", SubAddress:="'" & Worksheets(i).Name & "'" & "!A1", TextToDisplay:=Worksheets(i).Name
ActiveCell.Offset(1).Select
ActiveCell.EntireColumn.AutoFit
Next i
This starts the count at the 12th sheet as noted by i= 12 and then goes to the last sheet Worksheets.Count.
Also it's generally good practice to not select things, so here is a version without selecting a cell:
Sub links()
Dim ws As Worksheet
Set ws = Worksheets("General Information")
For i = 12 To ActiveWorkbook.Worksheets.Count
ws.Hyperlinks.Add Anchor:=ws.Cells(i + 2, 23), Address:="", SubAddress:="'" & Worksheets(i).Name & "'" & "!A1", TextToDisplay:=Worksheets(i).Name
Next i
Cells(1, 23).EntireColumn.AutoFit
End Sub
And for a more dynamic approach, as inspired by sbgib:
Sub menu()
Dim ws As Worksheet, printRow As Long, startCol As Long
Const startSheet As Long = 12 '- Which sheet number to start from
printCol = 23 '- Column "W" is column number 23
printRow = 14 '- First row to add hyperlinks to
Set ws = Worksheets("General Information")
printRow = printRow - startSheet
For i = startSheet To ActiveWorkbook.Worksheets.Count
ws.Hyperlinks.Add Anchor:=ws.Cells(printRow + i, printCol), Address:="", SubAddress:="'" & Worksheets(i).Name & "'" & "!A1", TextToDisplay:=Worksheets(i).Name
Next i
Cells(1, printCol).EntireColumn.AutoFit
End Sub