How to use WITH with an array of ranges - excel

Question

I need to set the borders for a bunch of ranges.
This is how I do it:
For n = 1 to record_num
With ThisWorkbook.Sheets("Sheet1").Range("A" & (n-1)*3 + 1 & ":C" & (n-1)*3 + 2)
With .Borders(xlEdgeLeft)
.LineStyle = xlContinuous
.ThemeColor = 6
.TintAndShade = -0.499984740745262
.Weight = xlThick
End With
... some other border codes
End With
Next n
Because For ... Next is always slow, I'm thinking of putting the ranges in an array and set the borders all at once.
With ThisWorkbook.Sheets("Sheet1")
For n = 1 to record_num
Set cellArray(i) = .Range("A" & (n-1)*3 + 1 & ":C" & (n-1)*3 + 2)
Next i
End With
This loop works fine. I then tried to do a With cellArray(), With Range(cellArray()), With ThisWorkbook.Sheets("Sheet1").Range(cellArray()) and they all failed with the error message of "Method 'Range' of object '_Global' failed".
What is the proper syntax of doing it?

Answer 1

Format With Offset
Range.Union
Option Explicit
Sub formatWithOffset()
Dim record_num As Long
' e.g.;
record_num = 5
Dim rng As Range
Set rng = ThisWorkbook.Worksheets("Sheet1").Range("A1:C2")
Dim tRng As Range
Dim n As Long
For n = 1 To record_num
If Not tRng Is Nothing Then
Set tRng = Union(tRng, rng.Offset((n - 1) * 3))
Else
Set tRng = rng
End If
Next n
If Not tRng Is Nothing Then
With tRng
With .Borders(xlEdgeLeft)
.LineStyle = xlContinuous
.ThemeColor = 6
.TintAndShade = -0.499984740745262
.Weight = xlThick
End With
End With
End If
End Sub

Answer 2

If you want to use With with an array, you need to iterate through each element of the array individually, as the With operator only operates on a single object.
This assigns the ranges to the cellarray:
Dim cellarray(1 To 5) As Range
With ThisWorkbook.Sheets("Sheet1")
For n = 1 To 5
Set cellarray(n) = .Range("A" & (n - 1) * 3 + 1 & ":C" & (n - 1) * 3 + 2)
Next n
End With
and then run through the elements of cellarray, and use With to apply the styles.
For Each c In cellarray
With c
.Interior.ColorIndex = 12
End With
Next c