Insert missing data then add data to two previous columns A & B - excel

Question

below is a VBA that when launched I get an error code of 'Run-Time error '13: Type Mismatch'.
It had worked perfectly before for General Format "dd mmm yyyy hhmm". After a couple of other VBAs it now in a Custom Format "dd mmm yyyy hhmm". The end goal is to have a blank row inserted where a date is skipped over, and have "NO DEPARTURS" placed in the blank row Column A, and for Column B and C have "N/A", and for Column D input the Missing Date in "dd mmm yyyy 0000". When debugged the line beginning with d1= cdate... is highlighted.
Sub Missing_date()
Dim d1 As Date, d2 As Date
r = 1
start:
If Cells(r + 1, "D") = "" Then Exit Sub
d1 = CDate(Split(Cells(r, "D"), " ")(1) & ", " & Split(Cells(r, "D"), " ")(0) & " " & Split(Cells(r, "D"), " ")(2))
d2 = CDate(Split(Cells(r + 1, "D"), " ")(1) & ", " & Split(Cells(r + 1, "D"), " ")(0) & " " & Split(Cells(r + 1, "D"), " ")(2))
If d2 - d1 >= 2 Then
Rows(r + 1).Insert shift:=xlDown
Cells(r + 1, "D") = Format(d1 + 1, "dd mmm yyyy 0000")
Cells(r + 1, "A") = "NO DEPARTURES"
Cells(r + 1, "B") = "N/A"
Cells(r + 1, "C") = "N/A"
End If
r = r + 1
GoTo start
End Sub

Answer 1

You are going to an awful lot of trouble trying to handle dates your own way rather than what Excel would like. I have taken the liberty of presuming that you had no intention of declaring war on Excel. Please try this code.
Option Explicit
Sub InsertMissingDates()
' 111
Dim NextDate As Variant
Dim CellVal As Variant
Dim R As Long ' loop counter: Rows
R = Cells(Rows.Count, "D").End(xlUp).Row
NextDate = CellDate(Cells(R, "D"))
If NextDate = vbError Then Exit Sub
' bottom rows must be inserted before top rows
For R = R - 1 To 2 Step -1
CellVal = CellDate(Cells(R, "D"))
If CellVal = vbError Then Exit For ' exit if date can't be recognised
Do While Int(CDbl(CellVal)) < Int(CDbl(NextDate - 1))
Rows(R + 1).Insert Shift:=xlDown
With Cells(R + 1, "D")
.Value = Int(CDbl(NextDate - 1))
.NumberFormat = "dd mmm yyyy hhmm"
.HorizontalAlignment = xlLeft
End With
Cells(R + 1, "A").Value = "NO DEPARTURES"
Cells(R + 1, "B").Value = "N/A"
Cells(R + 1, "C").Value = "N/A"
NextDate = NextDate - 1
Loop
NextDate = CellVal
Next R
End Sub
Private Function CellDate(Cell As Range) As Variant
' 111
' return vbError if cell's value couldn't be converted to a date
Dim Fun As Variant ' function return value
Dim CellVal As Variant
Dim Sp() As String
CellVal = Cell.Value
If IsDate(CellVal) Then
Fun = CDate(CellVal)
Else
Sp = Split(CellVal, " ")
If UBound(Sp) = 3 Then
Sp(3) = Right("0000" & Sp(3), 4)
Sp(3) = Left(Sp(3), 2) & ":" & Right(Sp(3), 2)
On Error Resume Next
Fun = CDate(Join(Sp))
End If
End If
If VarType(Fun) <> vbDate Then
MsgBox """" & CellVal & """ in row " & Cell.Row & vbCr & _
"couldn't be converted to a date.", _
vbInformation, "Data format error"
Fun = vbError
End If
CellDate = Fun
End Function
The point is that Excel takes a date to be an integer number, like 44135. Tomorrow will be 44136. Therefore each day = 1 and, therefore, each hour = 1/24. 44135.0 is 12AM and 43135.5 denotes 12PM. To display these numbers like 31 Oct 2020 1200 you don't format the number but you format the cell. This is what my code does.
Now you will have cells in your worksheet which have text that looks like a date (your entries) and dates that look like text (entries made by my code). Consider concocting a procedure which looks at the NumberFormat of each cell and changes its value to a proper date if it's Text, applying the reqired format at the same time. You can use lines of code from my above procedures to put it together. Then the function CellDate would become obsolete because its sole job is to mediate between your text dates and Excel's intentions.