Extract data from multiple worksheets to one sheet using vba - excel

Question

I have a workbook contain about 50 worksheets (sheet 1, sheet 2, sheet 3,........, sheet 50).
I want to get the data in all of them into one sheet. I used following code for that.
Sub tgr()
Dim ws As Worksheet
Dim wsDest As Worksheet
Set wsDest = Sheets("Sheet1")
For Each ws In ActiveWorkbook.Sheets
If ws.Name <> wsDest.Name Then
'ws.Range("A2", ws.Range("A22:Y500").End(xlToRight).End(xlDown)).Copy
ws.Range("A12:Y60").Copy
wsDest.Cells(Rows.Count, "A").End(xlUp).Offset(1, 0).PasteSpecial xlPasteValues
End If
'ActiveWorkbook.Save
Next ws
End Sub
But this code isn't working for all the sheets i have. it applies to random sheets.
What should i do to make it apply for all the sheets. (I have different rows in each sheet.)
And also above code runs for a long time.

Answer 1

The following code will consolidate data from all sheets in the workbook that is running the code.
Note that this is pasting just values (not formmating or formulas)
EDIT: Just for making this answer more clear. Using full qualifying of the target workbook and preventing to work with the active workbook, will guarantee that your looping through all the sheets. I address OPs request of looping through all sheets and not random ones. And also add a way to speed up the process.
Read the comments and adjust it to fit your needs:
Public Sub ConsolidateData()
' Declare and initialize the destination sheet
Dim destinationSheet As Worksheet
Set destinationSheet = ThisWorkbook.Worksheets("Sheet1")
' Loop through all worksheets in the workbook that is running the script
Dim sourceSheet As Worksheet
For Each sourceSheet In ThisWorkbook.Worksheets
If sourceSheet.Name <> destinationSheet.Name Then
' Set the source sheet's range
Dim sourceRange As Range
Set sourceRange = sourceSheet.UsedRange ' I'm using used range, but you could leave it as you had it in terms of a fixed range: sourceSheet.Range("A12:Y60").Copy
' Get first available cell in column A (from bottom to top)
Dim targetCell As Range
Set targetCell = destinationSheet.Range("A" & destinationSheet.Cells(destinationSheet.Rows.Count, "A").End(xlUp).Row).Offset(1, 0)
' Resize and assign values from source range (using value2 speeeds up things)
targetCell.Resize(sourceRange.Rows.Count, sourceRange.Columns.Count).Value2 = sourceRange.Value2
End If
Next sourceSheet
End Sub