How do you average values in a Do Until Loop? - excel

Question

I am attempting to write a code to average values in a particular column. I have a table with 5 columns, Column number 2 has the date/time, and column number 5 has a measurement. There are over 500 lines of data, one for each minute of the test, and my goal is to write a code to take all the data and average it down to 15 minute intervals.
I attempted this by starting my active cell on the first line of the table, and inserting a row, offsetting the active cell to take the value of the row below (date/time of minute 15) and move it into the newly inserted row. Then, to average the 15 rows of data for column 5 and input it into the inserted row in column 5. I attempted to do this with an iterative process but I cant get the macro to average the value.
Could someone please assist? - new to VBA, any help is appreciated.
Thanks
'Averages PID Values to 15 min intervals
Sub Make_Data_Box()
' Databoxes_1 Macro
Do Until IsEmpty(ActiveCell)
Dim loc As String
loc = ActiveCell.Value
Dim iter_1 As Integer
iter_1 = 1
Do Until ActiveCell.Value <> ActiveCell.Offset(iter_1, 0).Value
iter_1 = iter_1 + 1
Loop
ActiveCell.EntireRow.Insert
ActiveCell.Offset(iter_1, 1).Select
ActiveCell.Offset(-iter_1, 0).Value = ActiveCell.Value
ActiveCell.Offset(iter_1 - 1, 2).Select
ActiveCell.Value = Application.WorksheetFunction.Average(Range("ActiveCell:ActiveCell - 14"))
' ActiveSheet.Range(ActiveCell) = Application.WorksheetFunction.Average(ActiveSheet.Range("ActiveCell:ActiveCell+14"))
ActiveCell.Offset(-iter_1 + 1, 0).Value = ActiveCell.Value
ActiveCell.Offset(iter_1 + 14, -2).Select
Loop
End Sub

Answer 1

Sub Make_Data_Box()
Dim ws As Worksheet
Dim rngData As Range
Dim rngAvg As Range
Dim idx As Long
Dim AvgCol As Long
Dim DataCol As Long
Dim AveragePeriod As Long
Application.Calculation = xlCalculationManual
Application.ScreenUpdating = False
Set ws = ActiveSheet ' or specify sheet you want
' Get reference to Data Values range, this assume there are Headers in Row 1, Data from Row 2
DataCol = 5 ' Column number containing data
Set rngData = ws.Range(ws.Cells(2, DataCol), ws.Cells(ws.Rows.Count, DataCol).End(xlUp))
' Column to put Average in
AvgCol = 6 ' adjust to place Average where you want it
AveragePeriod = 15 ' Take average of this number of rows
For idx = AveragePeriod To rngData.Rows.Count Step AveragePeriod ' fill every AveragePeriod cell with average
rngData.EntireRow.Cells(idx, AvgCol) = _
WorksheetFunction.Average(rngData.Cells(idx, 1).Offset(1 - AveragePeriod, 0).Resize(AveragePeriod, 1))
Next
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True
End Sub
Or, if you want to insert a row for the AVERAGES, work from the bottom up
Sub Make_Data_Box2()
Dim ws As Worksheet
Dim rngData As Range
Dim rngAvg As Range
Dim idx As Long
Dim AvgCol As Long
Dim DataCol As Long
Dim AveragePeriod As Long
Application.Calculation = xlCalculationManual
Application.ScreenUpdating = False
Set ws = ActiveSheet ' or specify sheet you want
' Get reference to Data Values range, this assume there are Headers in Row 1, Data from Row 2
DataCol = 5 ' Column number containing data
Set rngData = ws.Range(ws.Cells(2, DataCol), ws.Cells(ws.Rows.Count, DataCol).End(xlUp))
' Column to put Average in
AvgCol = 6 ' adjust to place Average where you want it
AveragePeriod = 15 ' Take average of this number of rows
For idx = (rngData.Rows.Count \ 15) * 15 To 1 Step -AveragePeriod ' fill every 15th cell with average
With rngData.Cells(idx, 1)
.EntireRow.Insert
.Offset(-1, AvgCol - DataCol) = _
WorksheetFunction.Average(.Offset(-AveragePeriod, 0).Resize(AveragePeriod, 1))
End With
Next
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True
End Sub