Trying to update an excel table using a multiselect form - excel

Question

I'm creating a simple log that will update a table of devices to show when the last firmware update was and who updated it. I have a form that will update a single device entry correctly, but I can't get it to work with multiselect. It will only update the last item in the list.
How can I get it so that a that someone can update multiple entries with their name and date in a single use of the form? I think I need to loop through the selected index values (for loop?), but I'm just not seeing it.
Private Sub UpdateButton_Click()
EditIndex = Me.UpdateDevice.ListIndex
If EditIndex = -1 Then
MsgBox "No device was selected", vbExclamation, "Update Log"
Else
EditIndex = EditIndex + 2
Devices.Range("F" & EditIndex) = Me.DateUpdated
Devices.Range("G" & EditIndex) = Me.UpdatedBy
Unload Me
End If
MsgBox "Log has been successfully updated", vbExclamation, "Update Log"
End Sub
EditIndex is a public variable I have saved in a module to use across various forms in this file.

Answer 1

Private Sub UpdateButton_Click()
EditIndex = Me.UpdateDevice.ListIndex
Dim i As Integer
Dim rmaster As Long
If EditIndex = -1 Then
MsgBox "No device was selected", vbExclamation, "Update Log"
Exit Sub
Else
For i = 0 To Me.UpdateDevice.ListCount - 1
If Me.UpdateDevice.Selected(i) Then
rmaster = i + 2
Devices.Range("F" & rmaster) = Me.DateUpdated.Value
Devices.Range("G" & rmaster) = Me.UpdatedBy.Value
Debug.Print (Me.UpdateDevice.List(i))
Debug.Print rmaster
Else
End If
Next i
Unload Me
End If
MsgBox "Log has been successfully updated", vbExclamation, "Update Log"
End Sub
I kept the debug.print to see if it was returning correctly. Only returns the first selected item if I try to update the columns.

Answer 2

ListBox to Update Worksheet
ListIndex will return -1 only if the list box is empty (not populated).
Objects
Command Button - UpdateButton
List Box - UpdateDevice
Text Box - DateUpdated
Text Box - UpdatedBy
Worksheet - Devices
All controls are on a user form.
Devices is the code name of the worksheet.
The Code
Option Explicit
Private Sub UpdateButton_Click()
Dim ItemsCount As Long
Dim i As Long
With Me.UpdateDevice
For i = 0 To .ListCount - 1
If .Selected(i) Then
ItemsCount = ItemsCount + 1
EditIndex = i + 2 ' EditIndex is maybe not needed!?
Devices.Range("F" & EditIndex) = Me.DateUpdated
Devices.Range("G" & EditIndex) = Me.UpdatedBy
End If
Next i
End With
' I don't know why, but I needed the following line to see the complete
' change in worksheet 'Devices' (CodeName) before the MsgBox:
'Application.ScreenUpdating = True
Select Case ItemsCount
Case 0
MsgBox "No device was selected", vbExclamation, "Update Log"
Case 1
MsgBox "Log has been successfully updated with 1" _
& " entry.", vbInformation, "Update Log"
Case Else
MsgBox "Log has been successfully updated with " & ItemsCount _
& " entries.", vbInformation, "Update Log"
End Select
Unload Me
End Sub

Answer 3

The .ListIndex property only returns the index of the last selected item from a multiselect enabled listbox control. You'll have to iterate though all the items in the list and check to see if they have been selected. Note that .ListCount returns the number of items in the listbox control starting with 1 while the .Selected(i) references the list index values which start at 0. (i.e. if the listbox has one item in it, .ListCount returns 1 while .ListIndex returns 0 because there is 1 item in the list, but it is the item at the 0th index).
For i = 0 To Me.lsBox.ListCount - 1
If Me.lsBox.Selected(i) Then
'record was selected
'do something
Debug.Print (Me.lsBox.List(i))
Else
'record was not selected
'do nothing
End If
Next i
Edit 1 - In action
Edit 2 - OPs updated code exactly