Keep results of last run of the day only - excel

Question

My goal is to make a script that every time I press the button refreshes my investment value and then posts the date and the investment value on another sheet.
I managed the following code.
Sub Refresh()
ActiveWorkbook.RefreshAll
ActiveSheet.Range("A1").End(xlDown).Offset(1, 0).Value = Date
Worksheets("Portfolio").Range("B3").Copy
ActiveSheet.Range("B1").End(xlDown).Offset(1, 0).PasteSpecial Paste:=xlPasteValues
End Sub
If I hit the button more than once, I just want to keep the last entry of the day.
My idea was to solve it with an if else, but it ignores the if:
Sub Refresh()
ActiveWorkbook.RefreshAll
If ActiveSheet.Range("A1").End(xlDown).Offset(1, 0).Value = ActiveSheet.Range("A1").End(xlDown).Value Then
Worksheets("Portfolio").Range("B3").Copy
ActiveSheet.Range("B1").End(xlDown).PasteSpecial Paste:=xlPasteValues
Else
ActiveSheet.Range("A1").End(xlDown).Offset(1, 0).Value = Date
Worksheets("Portfolio").Range("B3").Copy
ActiveSheet.Range("B1").End(xlDown).Offset(1, 0).PasteSpecial Paste:=xlPasteValues
End If
End Sub

Answer 1

Update Worksheet
If you don't have a button or another control to run Refresh on the ActiveSheet, I would strongly suggest you define it like Protfolio is defined.
If the code is in the ActiveWorkbook, you should definitely use
ThisWorkbook instead, which refers to the workbook containing this
code.
The Code
Option Explicit
Sub Refresh()
' Define workbook ('wb').
Dim wb As Workbook
Set wb = ActiveWorkbook
' Do.
wb.RefreshAll
' Define Target Worksheet ('tgt').
Dim tgt As Worksheet
Set tgt = wb.ActiveSheet
' Define Old Date Cell ('cel').
Dim cel As Range
Set cel = tgt.Range("A1").End(xlDown)
' Check if Old Date Cell does not contain today's date.
If cel.Value <> Date Then
' Does not contain today's date:
' Define New Date Cell ('cel'), the cell below Old Date Cell.
Set cel = cel.Offset(1, 0)
' Write today's date to New Date Cell.
cel.Value = Date
Else
' Does contain today's date:
' Do nothing because Old Date Cell is becoming New Date Cell.
End If
' Define Source Worksheet ('src').
Dim src As Worksheet
Set src = wb.Worksheets("Portfolio")
' Write value from Source Cell to Target Cell.
' (Source Cell is next to New Date Cell).
cel.Offset(0, 1).Value = src.Range("B3").Value
End Sub