Find function in Excel VBA only refers to newly created sheet - excel

Question

I have been racking my brain on a bug whereby VBA seems to be using the wrong sheet within a Find function. For purposes such as printing the name of the sheet and values within cells, VBA refers to the sheet I expect. But for the Find function, it reverts to the most recently created sheet and I cannot force a reference to any other sheet. Below is an example that illustrates the problem. The lastRow variable gets assigned based on the Find function from the newly created sheet (three row) whereas the sht variable refers to the five row sheet.
Option Explicit
Dim wb As Workbook
Sub start()
Set wb = ThisWorkbook
Call make5RowSheet
Call make3RowSheet
Call CountRows5RowSheet
End Sub
Sub CountRows5RowSheet()
Dim thing As Variant
Dim sht As Worksheet
Dim lastRow As Long
For Each thing In wb.Worksheets
If LCase(thing.Name) = LCase("five rows") Then Set sht = thing
Next thing
With sht
lastRow = Cells.Find(What:="*", _
After:=.Range("A1"), _ '!!! .range here should refer to five row sheet, but lastRow gets set to 3
LookAt:=xlPart, _
LookIn:=xlFormulas, _
SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious, _
MatchCase:=False).Row
End With
Debug.Print "sheet name: " & sht.Name 'prints "five rows" as expected
Debug.Print "Cell(3,3) value: " & sht.Cells(3, 1).Value 'blank, as expected
Debug.Print "cell(5,5) value: " & sht.Cells(5, 1).Value 'prints "foo", as expected
Debug.Print "last Row: " & lastRow 'prints 3, which is puzzling
End Sub
Sub make5RowSheet()
Dim sht As Worksheet
Set sht = wb.Worksheets.Add
sht.Name = "five rows"
sht.Cells(5, 1) = "foo"
End Sub
Sub make3RowSheet()
Dim sht As Worksheet
Set sht = wb.Worksheets.Add
sht.Name = "three rows"
sht.Cells(3, 1).Value = "foo"
End Sub

Answer 1

Here
With sht
lastRow = Cells.Find(What:="*", _
Cells is not tied to sht so it refers to the ActiveSheet
With sht
lastRow = .Cells.Find(What:="*", _
should fix things

Answer 2

Your Cells.Find will be executed on whatever sheet is active.
In your case, the last sheet that was created is three rows.
So to avoid this hassle, make sure you Activate the right sheet right before you Find.
sht.Activate ' move from (three rows) to (five rows)
With sht
lastRow = Cells.Find(What:="*", _
After:=.Range("A1"), _ '!!! .range here should refer to five row sheet, but lastRow gets set to 3
LookAt:=xlPart, _
LookIn:=xlFormulas, _
SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious, _
MatchCase:=False).Row
End With