Loop to update column is not working correctly - excel

Question

I have a worksheet with data in Column A and Column B, I want to update Column C based on a condition that If
cellB is found in cellA, then cellB is written in Column C on the row of the match from column A.
With the help of the community, I have managed to come up with something but
can someone please tell me why the below loop only works for a few number of rows?
Also, sometimes Column B can be blank, is this a problem? If so, can i skip it if blank?
This works (perhaps its because all the cells have data in them):
Option Explicit
Sub Button2_Click()
Dim cellB As Range
Dim cellA As Range
For Each cellB In Range("b2:b5")
For Each cellA In Range("a2:a5")
If InStr(cellA, cellB) > 0 Then
Range("c" & cellA.Row) = cellB
End If
Next cellA
Next cellB
End Sub
This attempts to update Column C but the cellB values are never updated in the Column C (perhaps its because Column B contain nulls?):
Option Explicit
Sub Button2_Click()
Dim cellB As Range
Dim cellA As Range
For Each cellB In Range("b2:b500")
For Each cellA In Range("a2:a500")
If InStr(cellA, cellB) > 0 Then
Range("c" & cellA.Row) = cellB
End If
Next cellA
Next cellB
End Sub
Snapshot of the worksheet:

Answer 1

Try this way, plase. It will process all existing range, based on the A:A column filled range. It uses an array to collect the processing result and it should be fast enough:
Dim cellB As Range, cellA As Range, sh As Worksheet, lastRow As Long
Dim arrfin As Variant
Set sh = ActiveSheet 'use here your necessary sheet
lastRow = sh.Range("A" & Rows.count).End(xlUp).row
ReDim arrfin(1 To lastRow, 1 To 1)
sh.Range("C:C").Clear
For Each cellA In Range("a2:a" & lastRow)
For Each cellB In Range("b2:b" & lastRow)
If cellA.value <> "" And cellB.value <> "" Then
If InStr(cellA.value, cellB.value) > 0 Then
arrfin(cellA.row, 1) = cellB.value
End If
End If
Next cellB
Next cellA
sh.Range("C1").Resize(UBound(arrfin, 1), UBound(arrfin, 2)).value = arrfin

Answer 2

'For Next' vs 'For Each Next' feat. 'Range' vs 'Cells'
All five examples do the same thing.
They are best copied into a standard module (e.g. Module1) and are then easily run from VBE or called via a Button click event e.g.
Option Explicit
Sub Button2_Click()
updateForEachNextCellsVersion
End Sub
There are two For loops: the For Next loop and the For Each Next loop.
The first two examples use the For Each Next loop, while the remaining two use the For Next loop.
The 1st and 3rd example use Cells, while the 2nd and 4th use Range.
Why would you use Cells when Range is so much easier? You should know both. The biggest downside of Range is that you cannot loop through a row incrementing the columns. For this task only Cells can be used.
The usage of Cells with column numbers is shown in the 5th example.
The Code
Option Explicit
Sub updateForEachNextCellsVersion()
' Calculate the row of the last non-blank cell in column A.
Dim LastRow As Long: LastRow = Cells(Rows.Count, "A").End(xlUp).Row
' Declare the cell ranges for column A and B.
Dim celA As Range, celB As Range
' Loop through rows of column A.
For Each celA In Range(Cells(2, "A"), Cells(LastRow, "A")).Cells
' Loop through rows of column B.
For Each celB In Range(Cells(2, "B"), Cells(LastRow, "B")).Cells
' Check if the current cell in column B is not blank.
If Not IsEmpty(celB) Then
' Check if the values of the current cells in columns A and B
' are equal.
If celA.Value = celB.Value Then
' Write value of current cell in column B to
' column C, to the row of current cell in column A.
Cells(celA.Row, "C").Value = celB.Value
End If
End If
Next celB
Next celA
End Sub
Sub updateForEachNextRangeVersion()
' Calculate the row of the last non-blank cell in column A.
Dim LastRow As Long: LastRow = Range("A" & Rows.Count).End(xlUp).Row
' Declare the cell ranges for column A and B.
Dim celA As Range, celB As Range
' Loop through rows of column A.
For Each celA In Range("A2:A" & LastRow).Cells
' or: For Each celA In Range("A2", "A" & LastRow).Cells
' Loop through rows of column B.
For Each celB In Range("B2:B" & LastRow).Cells
' or: For Each celB In Range("B2", "B" & LastRow).Cells
' Check if the current cell in column B is not blank.
If Not IsEmpty(celB) Then
' Check if the values of the current cells in columns A and B
' are equal.
If celA.Value = celB.Value Then
' Write value of current cell in column B to
' column C, to the row of current cell in column A.
Range("C" & celA.Row).Value = celB.Value
End If
End If
Next celB
Next celA
End Sub
Sub updateForNextCellsVersion()
' Calculate the row of the last non-blank cell in column A.
Dim LastRow As Long: LastRow = Cells(Rows.Count, "A").End(xlUp).Row
' Declare the counters for the loops (i for column A, j for column B).
Dim i As Long, j As Long
' Loop through rows of column A.
For i = 2 To LastRow
' Loop through rows of column B.
For j = 2 To LastRow
' Check if the current cell in column B is not blank.
If Not IsEmpty(Cells(j, "B")) Then
' Check if the values of the current cells in columns A and B
' are equal.
If Cells(i, "A").Value = Cells(j, "B").Value Then
' Write value of current cell in column B to
' column C, to the row of current cell in column A.
Cells(i, "C").Value = Cells(j, "B").Value
End If
End If
Next j
Next i
End Sub
Sub updateForNextRangeVersion()
' Calculate the row of the last non-blank cell in column A.
Dim LastRow As Long: LastRow = Range("A" & Rows.Count).End(xlUp).Row
' Declare the counters for the loops (i for column A, j for column B).
Dim i As Long, j As Long
' Loop through rows of column A.
For i = 2 To LastRow
' Loop through rows of column B.
For j = 2 To LastRow
' Check if the current cell in column B is not blank.
If Not IsEmpty(Range("B" & j)) Then
' Check if the values of the current cells in columns A and B
' are equal.
If Range("A" & i).Value = Range("B" & j).Value Then
' Write value of current cell in column B to
' column C, to the row of current cell in column A.
Range("C" & i).Value = Range("B" & j).Value
End If
End If
Next j
Next i
End Sub
Sub updateForNextCellsColumnNumbersVersion()
' Calculate the row of the last non-blank cell in column A.
Dim LastRow As Long: LastRow = Cells(Rows.Count, 1).End(xlUp).Row
' Declare the counters for the loops (i for column A, j for column B).
Dim i As Long, j As Long
' Loop through rows of column A.
For i = 2 To LastRow
' Loop through rows of column B.
For j = 2 To LastRow
' Check if the current cell in column B is not blank.
If Not IsEmpty(Cells(j, 2)) Then
' Check if the values of the current cells in columns A and B
' are equal.
If Cells(i, 1).Value = Cells(j, 2).Value Then
' Write value of current cell in column B to
' column C, to the row of current cell in column A.
Cells(i, 3).Value = Cells(j, 2).Value
End If
End If
Next j
Next i
End Sub