Maintaining Edit History while editing from userform VBA - excel

Question

I am using a userform which is used for both submitting entries and editing them if needed. I am auto populating the form if a person enters a unique id (Material verification checklist number) with the help of TextBox After Update function
Then the user can change any parameters and press edit button to edit the changes. All these things work fine.
There is a requirement to maintain the edit history of all the changes in a different sheet. I am stuck there. This is how the sheet will look:
I am stuck with the C, D and E columns which should capture what parameters were edited, and their old and new values.
This is my code for the edit function right now:
Sub Edit()
Application.DisplayAlerts = False
Application.ScreenUpdating = False
Application.AutomationSecurity = msoAutomationSecurityLow
Dim id As Range
Set id = Worksheets("Transport Assesment").Range("A:A").Find(what:=frm3.TextBox1.Value, LookIn:=xlValues)
Worksheets("Transport Assesment").Unprotect "Ramu#lt12"
id.Offset(, 1).Value = frm3.TextBox13.Value
id.Offset(, 2).Value = frm3.DTPicker2.Value
id.Offset(, 4).Value = frm3.ComboBox7.Value
id.Offset(, 3).Value = frm3.ComboBox8.Value
id.Offset(, 5).Value = frm3.ComboBox6.Value
id.Offset(, 25).Value = frm3.TextBox15.Value
id.Offset(, 6).Value = frm3.ComboBox1.Value
id.Offset(, 7).Value = frm3.TextBox2.Value
id.Offset(, 8).Value = frm3.ComboBox2.Value
id.Offset(, 9).Value = frm3.TextBox3.Value
id.Offset(, 10).Value = frm3.ComboBox3.Value
id.Offset(, 11).Value = frm3.TextBox4.Value
id.Offset(, 12).Value = frm3.ComboBox4.Value
id.Offset(, 13).Value = frm3.TextBox5.Value
id.Offset(, 14).Value = frm3.ComboBox5.Value
id.Offset(, 15).Value = frm3.TextBox6.Value
id.Offset(, 16).Value = frm3.DTPicker3.Value
id.Offset(, 17).Value = frm3.TextBox14.Value
id.Offset(, 18).Value = frm3.DTPicker4.Value
id.Offset(, 19).Value = frm3.TextBox9.Value
id.Offset(, 20).Value = frm3.DTPicker1.Value
id.Offset(, 26).Value = frm3.TextBox16.Value
Worksheets("Transport Assesment").Protect "Ramu#lt12"
ThisWorkbook.Save
End Sub
Please guide me on how should I capture the parameters changed, and their old and new values. Thanks

Answer 1

Suggest using a separate sub to handle comparing the values and updating the tracking info where there's a difference:
'globals for tracking any changes
Dim oldValues, newValues, titles
Sub Edit()
Application.DisplayAlerts = False
Application.ScreenUpdating = False
Application.AutomationSecurity = msoAutomationSecurityLow
Dim id As Range
oldValues = ""
newValues = ""
titles = ""
Set id = Worksheets("Transport Assesment").Range("A:A").Find( _
what:=frm3.TextBox1.Value, LookIn:=xlValues)
If Not id Is Nothing Then
Worksheets("Transport Assesment").Unprotect "Ramu#lt12"
LogChanges id.Offset(, 1), frm3.TextBox13.Value
LogChanges id.Offset(, 2), frm3.DTPicker2.Value
LogChanges id.Offset(, 4), frm3.ComboBox7.Value
LogChanges id.Offset(, 3), frm3.ComboBox8.Value
LogChanges id.Offset(, 5), frm3.ComboBox6.Value
'etc etc for rest of cells
If Len(titles) > 0 Then
'have changes - update the tracking sheet
End If
Worksheets("Transport Assesment").Protect "Ramu#lt12"
Else
MsgBox "No match found!"
End If
ThisWorkbook.Save
End Sub
'compare form value with existing: log any change and update cell if required
Sub LogChanges(c As Range, vNew)
With c
sep = IIf(Len(titles) > 0, ";", "") 'need a separator?
If .Value <> vNew Then
'track the changes
titles = titles & sep & .Parent.Cells(1, .Column).Value 'column titles in Row1
oldValues = oldValues & sep & ValueOrBlank(.Value) 'track old value
newValues = newValues & sep & ValueOrBlank(vNew) 'track new value
.Value = vNew 'update the cell
End If
End With
End Sub
Function ValueOrBlank(v)
ValueOrBlank = IIf(Len(v)>0, v, "[blank]")
End Function