Excel VBA HTML Import Formatting - excel

Question

I have been using the below vba from another thread and have modified it to allow html vs txt.
When it imports the HTML it works fine but the html is spread out over multiple rows and not contained to one cell.
Is there a way to restrict the html to once cell only?
I need all the html to be in one cell as I need to process about 500 html files regularly and i just require it to be in individual cells.
Any help appreciated.
Sub ImportTXTFiles()
Dim FSO As Object
Dim xlsheet As Worksheet
Dim qt As QueryTable
Dim txtfilesToOpen As Variant, txtfile As Variant
Application.ScreenUpdating = False
Set FSO = CreateObject("Scripting.FileSystemObject")
txtfilesToOpen = Application.GetOpenFilename _
(FileFilter:="Text Files (*.html), *.html", _
MultiSelect:=True, Title:="HTML Files to Open")
With ActiveSheet
For Each txtfile In txtfilesToOpen
importrow = 1 + .Cells(.Rows.Count, 1).End(xlUp).Row
' IMPORT DATA FROM TEXT FILE
With .QueryTables.Add(Connection:="TEXT;" & txtfile, _
Destination:=.Cells(importrow, 1))
.TextFileParseType = xlDelimited
.TextFileConsecutiveDelimiter = False
.TextFileTabDelimiter = False
.TextFileSemicolonDelimiter = False
.TextFileCommaDelimiter = False
.TextFileSpaceDelimiter = False
.TextFileOtherDelimiter = "$"
.Refresh BackgroundQuery:=False
End With
Next txtfile
For Each qt In .QueryTables
qt.Delete
Next qt
End With
Application.ScreenUpdating = True
MsgBox "Successfully imported text files!", vbInformation, "SUCCESSFUL IMPORT"
Set FSO = Nothing
End Sub

Answer 1

Try the next code, please:
Sub ImportTXTFiles()
Dim FSO As Object, txtStr As Object, strText As String, sh As Worksheet
Dim txtfilesToOpen As Variant, txtfile As Variant, importrow As Long
Set FSO = CreateObject("Scripting.FileSystemObject")
Set sh = ActiveSheet ' use here your sheet
txtfilesToOpen = Application.GetOpenFilename _
(FileFilter:="Text Files (*.html), *.html", _
MultiSelect:=True, Title:="HTML Files to Open")
For Each txtfile In txtfilesToOpen
importrow = 1 + sh.cells(Rows.count, 1).End(xlUp).Row
Set txtStr = FSO.OpenTextFile(txtfile)
strText = txtStr.ReadAll
txtStr.Close
If Len(strText) <= 32000 Then
sh.cells(importrow, 1).Value = strText:
Else
MsgBox txtfile & " size exceeds the limit of 32000 digits..."
End If
Next txtfile
MsgBox "Successfully imported text files!", vbInformation, "SUCCESSFUL IMPORT"
Set FSO = Nothing
End Sub
It checks the limit of a cell string size (32k characters) and rise a message for such a case... If necessary, it can split the string in portions of 32k and paste in the next cells, marking in B:B 1, 2 ... x portion numbers...