Excel: Moving a Table Row to Another Sheet's Table - excel

Question

Not very experienced with Excel coding, but I got a decent way myself. But I cant figure this thing out.
Looking to automate a sheet so that when a cell in column E is set to "Staffed", the macro will move the entire row from the table in Sheet A to the Table in Sheet B. At the moment, the macro is placing the cut and pasted row below the table, sometimes 20 something rows below, on the new sheet.
I would appreciate the help. Thank you
Sub NtS()
Dim xRg As Range
Dim xCell As Range
Dim I As Long
Dim J As Long
Dim K As Long
I = Worksheets("Clients Needing Staffed").UsedRange.Rows.Count
J = Worksheets("Clients Staffed").UsedRange.Rows.Count
If J = 1 Then
If Application.WorksheetFunction.CountA(Worksheets("Clients Staffed").UsedRange) = 0 Then J = 0
End If
Set xRg = Worksheets("Clients Needing Staffed").Range("E1:E" & I)
On Error Resume Next
Application.ScreenUpdating = False
For K = 1 To xRg.Count
If CStr(xRg(K).Value) = "Staffed" Then
xRg(K).EntireRow.Copy Destination:=Worksheets("Clients Staffed").Range("A" & J + 1)
xRg(K).EntireRow.Delete
If CStr(xRg(K).Value) = "Staffed" Then
K = K - 1
End If
J = J + 1
End If
Next
Application.ScreenUpdating = True
End Sub

Answer 1

Copy and Delete Rows (Union)
Option Explicit
Sub NtS()
' Constants
' Source
Const srcName As String = "Clients Needing Staffed"
Const srcFirstRow As Long = 2
Const srcLastRowCol As Variant = "E" ' e.g. 1 or "A", 5 or "E"...
Const srcCritCol As Variant = "E" ' e.g. 1 or "A", 5 or "E"...
Const srcCriteria As String = "Staffed"
' Target
Const tgtName As String = "Clients Staffed"
' The following parameter has to be 1 or "A", because copying entire row.
Const tgtFirstCol As Variant = "A" ' e.g. 1 or "A"
Const tgtFirstRowCol As Variant = "A" ' e.g. 1 or "A"
' Other
Dim wb As Workbook: Set wb = ThisWorkbook ' The workbook with this code.
' Source
Dim src As Worksheet: Set src = wb.Worksheets(srcName)
Dim srcLastRow As Long
srcLastRow = src.Cells(src.Rows.Count, srcLastRowCol).End(xlUp).Row
If srcLastRow < srcFirstRow Then Exit Sub
' Define Criteria column range.
Dim rng As Range: Set rng = src.Range(src.Cells(srcFirstRow, srcCritCol), _
src.Cells(srcLastRow, srcCritCol))
Application.ScreenUpdating = False
' Loop through each cell of Criteria column range to search
' for Criteria value.
Dim cel As Range, uRng As Range, i As Long, k As Long
For Each cel In rng.Cells
If cel.Value = srcCriteria Then
k = k + 1
If Not uRng Is Nothing Then
Set uRng = Union(uRng, cel.EntireRow)
Else
Set uRng = cel.EntireRow
End If
End If
Next cel
If uRng Is Nothing Then
MsgBox "Data has already been deleted.", vbExclamation, "Done Nothing"
Exit Sub
End If
' Target
' Define Target First Row.
Dim tgt As Worksheet: Set tgt = wb.Worksheets(tgtName)
Dim tgtFirstRow As Long
tgtFirstRow = tgt.Cells(tgt.Rows.Count, tgtFirstRowCol).End(xlUp).Row + 1
' Copy 'collected' range of rows to Target worksheet starting
' from Target First Cell.
uRng.Copy tgt.Cells(tgtFirstRow, tgtFirstCol)
' Delete 'collected' range of rows.
uRng.EntireRow.Delete
' Finish
Application.ScreenUpdating = True
' Inform user.
MsgBox "Data copied and deleted.", vbInformation, "Success"
End Sub