Populate a column with input based on partial match from another column - excel

Question

I have a sheet 1 where the column contains a list of domains e.g. www.nonsence.bg/sport, www.example.cn/streets, www.news.gr/sports
I would like to populate the Country input in column A based on the "KEY" table that is stored within the sheet 4 where column A = the domain (e.g. ".gr/", ".bg/", ".cn/") and column B = country (Greece, China, Bulgaria).
I use the following code for find/replace, but with the partial match it seems to be a bit more complex:
Sub substitute()
Dim Sh1 As Worksheet
Dim Sh2 As Worksheet
Dim FndList, x&
Set Sh1 = Sheets(1)
Set Sh2 = Sheets(3)
FndList = Sh2.Cells(1, 1).CurrentRegion
For x = 1 To UBound(FndList)
Sh1.Cells.Replace What:=FndList(x, 1), replacement:=FndList(x, 2), LookAt:=xlPart
Next
End Sub

Answer 1

Especially since your entries in KEY table are of the form xx/, it's pretty easy to do this with a formula:
I made the key table into a "real" table and am using structured references, but you can change that to normal references if you prefer
B2: =INDEX(tblKEY[Country], MATCH(TRUE,ISNUMBER(MATCH("*" & tblKEY[Domain]&"*",A2,0)),0))
KEY table
(named tblKEY)
Results
You can do the same thing with VBA and the Range.Find method, if you must use VBA for some other reason:
Option Explicit
Sub Country()
Dim wsSrc As Worksheet, LO As ListObject
Dim rSrc As Range, C As Range, CC As Range
'Change these to represent your actual locations
Set wsSrc = ThisWorkbook.Worksheets("sheet5")
Set rSrc = wsSrc.Cells(1, 1).CurrentRegion.Offset(rowoffset:=1)
Set LO = wsSrc.ListObjects("tblKEY")
Application.ScreenUpdating = False
rSrc.Columns(2).ClearContents
For Each CC In LO.DataBodyRange.Columns(1).Cells
With rSrc.Columns(1)
Set C = .Find(what:=CC.Value, LookIn:=xlValues, lookat:=xlPart, MatchCase:=False)
If Not C Is Nothing Then
C.Offset(0, 1) = CC.Offset(0, 1)
End If
End With
Next CC
End Sub

Answer 2

If I understood what you want correctly, this should work
Sub UpdateCountries()
Dim vCountriesList As Variant
Dim i As Long
Dim j As Long
Dim lLastRow As Long
With ThisWorkbook.Sheets("Sheet4")
vCountriesList = .Range(.Cells(2, "A"), .Cells(Rows.count, "B").End(xlUp)).Value
End With
With ThisWorkbook.Sheets("Sheet1")
lLastRow = .Cells(Rows.count, "H").End(xlUp).Row
For i = 2 To lLastRow
For j = 1 To UBound(vCountriesList, 1)
If InStr(1, .Cells(i, "H"), vCountriesList(j, 1), vbTextCompare) > 0 Then
If .Cells(i, "A").Value <> vCountriesList(j, 2) Then
.Cells(i, "A").Value = vCountriesList(j, 2)
End If
Exit For
End If
Next j
Next i
End With
End Sub