Two macros same worksheet - excel

Question

I’m a total newbie at this. I’ve got a worksheet with a list of jobs. One of the columns relate to the location eg, London, Manchester. When London is selected, I want that row copied to the London worksheet, and so on.
Also, I’ve got a column to show when the job is completed. So when I select completed, I want that row cut and pasted into the completed worksheet.
Now, after searching, I’ve found the code for both these actions and individually they work. But I’m trying to get them to work together. I’ve tried multiple things from searches I’ve done on here and google but nothing is working.
These are the codes I’ve got that work individually:
Private Sub Worksheet_Change(ByVal Target As Range)
Dim wsUse As Worksheet
Dim wsDc As Worksheet
Dim strdc As String
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
If Target.Cells.Count > 1 Then Exit Sub
If Target.Column <> 9 Then Exit Sub ' change 2 to the correct column number
Set wsUse = ThisWorkbook.Sheets("Workload Overview")
Set wsDc = ThisWorkbook.Sheets("Completed")
With wsUse
strdc = Target.Value
If strdc = "Completed" Then
n = .Rows.Count
Target.EntireRow.Copy
wsDc.Range("A" & n).End(xlUp).Offset(1, 0).PasteSpecial xlValues
wsDc.Range("A" & n).End(xlUp).EntireRow.PasteSpecial xlPasteFormats
Application.CutCopyMode = False
Target.EntireRow.Delete
End If
End With
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub
Private Sub Worksheet_Change(ByVal Target As Range)
Dim wsUse As Worksheet
Dim wsDc As Worksheet
Dim strdc As String
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
If Target.Cells.Count > 1 Then Exit Sub
If Target.Column <> 6 Then Exit Sub ' change 2 to the correct column number
Set wsUse = ThisWorkbook.Sheets("Workload Overview")
Set wsDc = ThisWorkbook.Sheets("London")
With wsUse
strdc = Target.Value
If strdc = "London" Then
n = .Rows.Count
Target.EntireRow.Copy
wsDc.Range("A" & n).End(xlUp).Offset(1, 0).PasteSpecial xlValues
wsDc.Range("A" & n).End(xlUp).EntireRow.PasteSpecial xlPasteFormats
Application.CutCopyMode = False
Target.EntireRow.Copy
End If
End With
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub

Answer 1

Worksheet_Change is an event that Excel looks out for and the code should be in a worksheet module (rather than ThisWorkbook or a normal module).
You can only have one Worksheet_Change change code in a module - shouldn't compile with it twice as you have.
So you need to combine the two procedures into one.
I've made a couple of assumptions - you set wsDC to London. You were then going to add similar code for Manchester and any other city. If you can guarantee your selected cities will be the same as the sheet name then use that to find your sheet to paste to.
If column 9 isn't Completed (could be Cancelled, In Progress) then can exit the sub as well.
The only difference between a Completed record and a City record are that the completed ones are deleted, so that can be treated the same way as cities except the last IF block that checks whether it needs deleting or not.
Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo ErrorHandler 'Turn on error handling.
'You may not need to turn off calculation or screenupdating.
'Always polite to return it to the setting it was, rather than assuming
'so remember the setting so can be put back later.
Dim CalcMethod As Long
CalcMethod = Application.Calculation
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
'This is needed if the row is deleted.
'Deleting a row is a Change event which will cause this code to fire a second time.
Application.EnableEvents = False
If Target.Cells.Count > 1 Then Exit Sub
If Target.Column <> 9 And Target.Column <> 6 Then Exit Sub
If Target.Column = 9 And Target.Value <> "Completed" Then Exit Sub
'Assuming Target value will be the same as the sheet name if column 6,
'or a "Completed" if it's column 9.
'e.g. London, Manchester, New York, Completed.
Dim wsDc As Worksheet
Set wsDc = ThisWorkbook.Worksheets(Target.Value)
Target.EntireRow.Copy
wsDc.Cells(Rows.Count, 1).End(xlUp).Offset(1).PasteSpecial xlValues
wsDc.Cells(Rows.Count, 1).End(xlUp).Offset(1).PasteSpecial xlPasteFormats
If Target.Column = 9 And Target.Value = "Completed" Then
Application.CutCopyMode = False
Target.EntireRow.Delete xlShiftUp
End If
TidyExit:
'Turn everything back on.
Application.EnableEvents = True
Application.Calculation = CalcMethod
Application.ScreenUpdating = True
Exit Sub
'If an error occurs, skip to this section (which is outside the main body),
'deal with the error and jump back into the code so everything can be
'turned back on before exiting.
ErrorHandler:
MsgBox Err.Number & vbCr & Err.Description, vbOKOnly + vbCritical
Resume TidyExit
End Sub