How to split excel columns into multiple rows - excel

Question

I get exports from an event registration form, where each order(row) contains order date, purchase price, and info for between 1-4 registrants. Each registrant has columns for first name, last name, and date of birth. What I need is to split up these rows such that each individual person is on their own row, with first, last, and DOB on the row, ideally along with the other order information duplicated too.
This may be confusing so I have mockup date for the form I get exports in, and the form I'd like to convert them to.
What I get:
https://drive.google.com/file/d/1xt64Re2CTlbQnHuRy1dQaFeNV5OmETfW/view?usp=sharing
What I want:
https://drive.google.com/file/d/156WmiQ4Tx4JGB5FYLTqHBuVmJqi20pRZ/view?usp=sharing
I found this tutorial which seem very close to what I want using Excel Power Query, but it is describing a method for when the multiple items are in one column separated by comma. My situation is a bit different and I can't make it work.
Any ideas?

Answer 1

Below PowerQuery works on sample data set you had, when loaded into range Table1
Written dynamically for any number of First/Last/DOB sets of columns; You had 4 this would handle any number of them
Paste into Home ... Advanced Editor...
a bit long winded to separate the steps and make it visible
let Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
#"Changed Type" = Table.TransformColumnTypes(Source,{{"Order Date", type date}}),
// Get names of all First, Last and DOB fields
ColumnsToCombine1 = List.Select(Table.ColumnNames(#"Changed Type"), each Text.Contains(_, "(First)")),
ColumnsToCombine2 = List.Select(Table.ColumnNames(#"Changed Type"), each Text.Contains(_, "(Last)")),
ColumnsToCombine3 = List.Select(Table.ColumnNames(#"Changed Type"), each Text.Contains(_, "DOB")),
//Convert to Text, so we can merge columns; for date fields, convert to date first
#"Changed Type1" = Table.TransformColumnTypes(#"Changed Type", (List.Transform(ColumnsToCombine3 ,each {_,type date}))),
#"Changed Type2" = Table.TransformColumnTypes (#"Changed Type1",List.Transform(Table.ColumnNames(#"Changed Type1"), each {_, type text})),
// convert all First, Last and DOB fields into three comma separated columns
#"Combined1" = Table.AddColumn(#"Changed Type2" , "First", each Text.Combine(Record.FieldValues(Record.SelectFields(_,ColumnsToCombine1)),", ")),
#"Combined2" = Table.AddColumn(#"Combined1", "Last", each Text.Combine(Record.FieldValues(Record.SelectFields(_,ColumnsToCombine2)),", ")),
#"Combined3" = Table.AddColumn(#"Combined2", "DOB", each Text.Combine(Record.FieldValues(Record.SelectFields(_,ColumnsToCombine3)),", ")),
#"Removed Other Columns" = Table.SelectColumns(Combined3,{"ID", "Order Date", "Quantity", "Payment", "First", "Donate", "Last", "DOB"}),
//expand all comma separated columns into their own rows
TableTransform = Table.Combine(List.Transform(List.Transform(Table.ToRecords(#"Removed Other Columns" ), (x) => List.Transform(Record.ToList(x), each Text.Split(_,","))), each Table.FromColumns(_, Table.ColumnNames(#"Removed Other Columns" )))),
#"Reordered Columns" = Table.ReorderColumns(TableTransform,{"ID", "Order Date", "Quantity", "First", "Last", "DOB", "Payment", "Donate"}),
#"Filled Down" = Table.FillDown(#"Reordered Columns",{"ID", "Order Date", "Quantity", "Payment", "Donate"}),
#"Changed Type3" = Table.TransformColumnTypes(#"Filled Down",{{"DOB", type date}, {"Order Date", type date}, {"Payment", type number}, {"Donate", type number}, {"Quantity", type number}, {"First", type text}, {"Last", type text}})
in #"Changed Type3"
Alternate version, hard coded to 4 tables, based on Ron's
let Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
colNames = Table.ColumnNames(Source),
Table1 = Table.Skip(Table.DemoteHeaders(Table.SelectColumns(Source,List.RemoveMatchingItems(colNames , List.Select(colNames, each Text.Contains(_, "-2") or Text.Contains(_, "-3") or Text.Contains(_, "-4"))))),1),
Table2 = Table.Skip(Table.DemoteHeaders(Table.SelectColumns(Source,List.RemoveMatchingItems(colNames , List.Select(colNames, each Text.Contains(_, "-1") or Text.Contains(_, "-3") or Text.Contains(_, "-4"))))),1),
Table3 = Table.Skip(Table.DemoteHeaders(Table.SelectColumns(Source,List.RemoveMatchingItems(colNames , List.Select(colNames, each Text.Contains(_, "-1") or Text.Contains(_, "-2") or Text.Contains(_, "-4"))))),1),
Table4 = Table.Skip(Table.DemoteHeaders(Table.SelectColumns(Source,List.RemoveMatchingItems(colNames , List.Select(colNames, each Text.Contains(_, "-1") or Text.Contains(_, "-2") or Text.Contains(_, "-3"))))),1),
combined = Table1 & Table2 & Table3 & Table4,
#"Filtered Rows" = Table.SelectRows(combined, each ([Column4] <> null)),
#"Sorted Rows" = Table.Sort(#"Filtered Rows",{{"Column1", Order.Ascending}}),
#"Renamed Columns" = Table.RenameColumns(#"Sorted Rows",{{"Column2", "Order Date"}, {"Column3", "Quantity"}, {"Column4", "First"}, {"Column5", "Last"}, {"Column6", "DOB"}, {"Column7", "Payment"}, {"Column8", "Donate"}, {"Column1", "ID"}}),
#"Changed Type" = Table.TransformColumnTypes(#"Renamed Columns",{{"ID", type number}, {"Quantity", type number}, {"Payment", type number}, {"Donate", type number}, {"Order Date", type date}, {"DOB", type date}, {"First", type text}, {"Last", type text}})
in #"Changed Type"

Answer 2

Here is another PQ method to accomplish this.
I post it as a PQ beginner, and I have no idea whether this method or the first method posted is more efficient and/or scalable
It is still a work in progress, as I have fixed column names in some of the steps, and I want to make that more generalized eventually. But this problem of repeating groups of columns comes up from time to time.
Source Data
This method:
Reorder the columns to put the "common columns" together, which, in this case, would be the first three and the last two.
Demote the header row and transpose the table
Process the first column so as to create a proper list of what will be eventual column headers.
Split this table into multiple tables where
the first table represents the common columns
the other tables represent each repeating group of columns
Combine the first table with each of the other tables
Combine the resulting tables
Transpose back to the original column/row orientation, and promote the first row to headers.
Clean up by removing nulls and sorting
Reorder the columns to put the first three and last two back where they were initially.
Note: You'll need to change Table1 in the code to the actual table name, if it is different
let
Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
colNames = Table.ColumnNames(Source),
commonTableColumnCount = 5,
colOrder = List.Combine({List.FirstN(colNames,3),List.LastN(colNames,2),List.Range(colNames,3,List.Count(colNames)-commonTableColumnCount)}),
#"Reordered Columns" = Table.ReorderColumns(Source,colOrder),
//Demote Headers and transpose
transpose1 = Table.Transpose(Table.DemoteHeaders(#"Reordered Columns")),
//Split up Column 1 to create multiple matched names
split = Table.SplitColumn(transpose1, "Column1", Splitter.SplitTextByDelimiter("-", QuoteStyle.Csv), {"Column1", "Column1.1"}),
#"Split Column by Delimiter" = Table.SplitColumn(split, "Column1.1", Splitter.SplitTextByEachDelimiter({" "}, QuoteStyle.Csv, true), {"Column1.1.1", "Column1.1.2"}),
#"Removed Columns" = Table.RemoveColumns(#"Split Column by Delimiter",{"Column1.1.1"}),
#"Merged Columns" = Table.CombineColumns(#"Removed Columns",{"Column1", "Column1.1.2"},Combiner.CombineTextByDelimiter(" ", QuoteStyle.None),"Column1"),
commonTable = Table.Split(#"Merged Columns",commonTableColumnCount){0},
record = Table.ToRecords(commonTable),
//repeated tables
//rem CommonTables Rows and split
data = Table.Split(Table.RemoveRows(#"Merged Columns",0,commonTableColumnCount),3),
//insert common rows into each table
data1 = Table.InsertRows(data{0},0,record),
//get final order of column names
colNames2 = Table.Column(data1,"Column1"),
finalOrder = List.Combine({List.FirstN(colNames2,3),List.LastN(colNames2,List.Count(colNames2)-commonTableColumnCount), List.Range(colNames2,3,2)}),
custom1 = List.Transform(data, each Table.InsertRows(_,0,record)),
//Transpose and combine each Table
custom2 = List.Transform(custom1, each(Table.PromoteHeaders(Table.Transpose(_),[PromoteAllScalars=true]))),
#"Converted to Table" = Table.FromList(custom2, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
#"Expanded Column1" = Table.ExpandTableColumn(#"Converted to Table","Column1",colNames2),
//need to do this manually
#"Changed Type" = Table.TransformColumnTypes(#"Expanded Column1",{{"ID ", Int64.Type}, {"Order Date ", type date}, {"Quantity ", Int64.Type}, {"Payment ", Currency.Type}, {"Donate ", Currency.Type}, {"Name (First)", type text}, {"Name (Last)", type text}, {"DOB ", type date}}),
#"Filtered Rows" = Table.SelectRows(#"Changed Type", each ([#"Name (Last)"] <> null)),
#"Sorted Rows" = Table.Sort(#"Filtered Rows",{"ID ", Order.Ascending}),
#"Reordered Columns1" = Table.ReorderColumns(#"Sorted Rows", finalOrder)
in
#"Reordered Columns1"
Reordered Table