Function IIF in loop statement - excel

Question

I have a working code that loops through the rows of an array then store the values into another array. No problem at the code in fact but I am trying to improve my skills and learn new skills
This is the code
Sub Test()
Dim a, i As Long, j As Long, n As Long
a = Cells(1).CurrentRegion.Value
ReDim b(1 To UBound(a, 1) * UBound(a, 2))
For i = LBound(a) To UBound(a)
If i Mod 2 = 1 Then
For j = LBound(a, 2) To UBound(a, 2)
n = n + 1
If a(i, j) <> Empty Then b(n) = a(i, j)
Next j
Else
For j = UBound(a, 2) To LBound(a, 2) Step -1
n = n + 1
If a(i, j) <> Empty Then b(n) = a(i, j)
Next j
End If
Next i
Range("M2").Resize(n).Value = Application.Transpose(b)
End Sub
What I am trying to do is to compact the nested loop and this is my try
For j = iif(i mod2=1,LBound(a, 2) To UBound(a, 2),UBound(a, 2) To LBound(a, 2) Step -1)
But this seems not to ne valid. Any ideas?

Answer 1

This works well and I can figure it out with the help of the experts
Thanks a lot for everyone
Sub Test()
Dim a, i As Long, j As Long, n As Long
a = Cells(1).CurrentRegion.Value
ReDim b(1 To UBound(a, 1) * UBound(a, 2))
For i = LBound(a) To UBound(a)
For j = IIf(i Mod 2 = 1, LBound(a, 2), UBound(a, 2)) To IIf(i Mod 2 = 1, UBound(a, 2), LBound(a, 2)) Step IIf(i Mod 2 = 1, 1, -1)
n = n + 1
If a(i, j) <> Empty Then b(n) = a(i, j)
Next j
Next i
Range("N2").Resize(n).Value = Application.Transpose(b)
End Sub

Answer 2

Compacting Code
Option Explicit
Sub Test()
Dim a: a = Cells(1).CurrentRegion.Value
Dim ub1 As Long, ub2 As Long: ub1 = UBound(a): ub2 = UBound(a, 2)
ReDim b(1 To ub1 * ub2)
Dim i As Long, j As Long, n As Long, md As Long
For i = 1 To ub1
md = i Mod 2
For j = Abs(md - 1) * ub2 + md To md * ub2 + Abs(md - 1) _
Step 2 * (md - 1) + 1
n = n + 1
If a(i, j) <> Empty Then b(n) = a(i, j)
Next j
Next i
Range("M2").Resize(n).Value = Application.Transpose(b)
End Sub