Excel two column of different file comparison and replace next column - excel

Question

Hi I want to compare two excel files and if any strings in file1 coumun B batches with File2 ColumnA then I want to replace corresponding File2's ColumB with File1 Column C
eg:
if File 1, B3 matches with File2 A5 then I want to replace string in B5 of file 2 with C3 of file1

Answer 1

Assume that File1 location is "C:\test\File1.xlsx"
so you can import File1:column A values to File2:column K by formula
File2:K1 formule
='C:\test\[File1.xlsx]Sheet1'!A1
File2:K2 formule
='C:\test\[File1.xlsx]Sheet1'!A2
and so on
Now it is easy to write formulas in File2 depends on imported values

Answer 2

Column Comparison Worksheet Update
Carefully adjust the constants including the Workbooks.
Copy the code into a standard module (e.g. Module1).
The Code
Option Explicit
Sub updateWorksheet()
' Source
Const srcWb As String = "Source.xlsm"
Const srcWs As String = "Sheet1"
Const srcFirstRow As Long = 2
Const srcCriteria As Variant = "B"
Const srcValue As Variant = "C"
' Target
Const tgtWb As String = "Target.xlsm"
Const tgtWs As String = "Sheet2"
Const tgtFirstRow As Long = 2
Const tgtCriteria As Variant = "A"
Const tgtValue As Variant = "B"
' Workbooks
Dim wbSrc As Workbook: Set wbSrc = Workbooks(srcWb)
'Dim wbSrc As Workbook: Set wbSrc = ThisWorkbook
Dim wbTgt As Workbook: Set wbTgt = Workbooks(tgtWb)
'Dim wbTgt As Workbook: Set wbTgt = ThisWorkbook
' Write values from Source Range to Source Array.
Dim src As Worksheet: Set src = wbSrc.Worksheets(srcWs)
Dim rng As Range
Set rng = src.Columns(srcCriteria).Find("*", , xlValues, , , xlPrevious)
If rng Is Nothing Then Exit Sub
If rng.Row < srcFirstRow Then Exit Sub
Set rng = src.Range(src.Cells(srcFirstRow, srcCriteria), rng)
Dim Source(1) As Variant: Source(0) = rng.Value
Source(1) = rng.Offset(, src.Columns(srcValue).Column - rng.Column).Value
' Write values from Target Range to Target Array.
Dim tgt As Worksheet: Set tgt = wbTgt.Worksheets(tgtWs)
Set rng = tgt.Columns(tgtCriteria).Find("*", , xlValues, , , xlPrevious)
If rng Is Nothing Then Exit Sub
If rng.Row < tgtFirstRow Then Exit Sub
Set rng = tgt.Range(tgt.Cells(tgtFirstRow, tgtCriteria), rng)
Dim Target(1) As Variant: Target(0) = rng.Value
Set rng = rng.Offset(, tgt.Columns(tgtValue).Column - rng.Column)
Target(1) = rng.Value
Dim Curr As Variant
' Write from Source Array to Target Array.
Dim i As Long
For i = 1 To UBound(Target(0))
Curr = Application.Match(Target(0)(i, 1), Source(0), 0)
If Not IsError(Curr) Then
Target(1)(i, 1) = Source(1)(Curr, 1)
End If
Next i
' Write from Target Array to Target Range.
rng.Value = Target(1)
' Inform user.
MsgBox "Data transferred.", vbInformation, "Success"
End Sub