VBA Excel sheets copied in wrong order - excel

Question

Good morning,
I am using the following code:
Sub CABsheet()
Dim i As Long
Dim xNumber As Long
Dim xName As String
Dim ws As Worksheet
Application.ScreenUpdating = False
Set ws = Sheets("CAB1")
xNumber = Sheets("NIM & BADGER").Range("R27").Value
For i = 1 To Number
ws.Copy After:=ActiveWorkbook.Sheets(ws.Index + i - 1)
ActiveSheet.Name = "CAB" & i + 1
Next
ws.Activate
Application.ScreenUpdating = True
End Sub
but I am getting an error saying, that the sheet under this name already exists.
when I use a bit changed code like this:
Sub CABsheet()
Dim i As Long
Dim xNumber As Long
Dim xName As String
Dim ws As Worksheet
Application.ScreenUpdating = False
Set ws = Sheets("CAB1")
xNumber = Sheets("NIM & BADGER").Range("R27").Value
For i = 2 To Number
ws.Copy After:=ActiveWorkbook.Sheets(ws.Index + (i - 2))
ActiveSheet.Name = "CAB" & (i + 1) + 2
Next
ws.Activate
Application.ScreenUpdating = True
End Sub
then an error is gone, and everything seems to be alright but...
... i am getting numeration from CAB5 onwards instead of CAB 2
If I change a bit of my code again...
For i = 2 To xNumber
ws.Copy After:=ActiveWorkbook.Sheets(ws.Index + (i - 1))
ActiveSheet.Name = "CAB" & i + 2
Next
then order is wrong.
The tabs are from CAB4 onwards.
I need them from CAB2 onwards.
I can't remove +2 because the debugger shows me an error, that the name already been taken.
What can I fix in this code?

Answer 1

In your very first code example you
Dim xNumber As Long
you set a value for it
xNumber = Sheets("NIM & BADGER").Range("R27").Value
and then you use the variable Number instead of xNumber in your loop:
For i = 2 To Number
The variable Number is not declared nor initialized with a value and therefore it is 0.
So this cannot work. Make sure you use Option Explicit so you get notified if you use a worng variable name that was not declared.
I also recommend not to use ActiveSheet
Option Explicit
Public Sub CABsheet()
Application.ScreenUpdating = False
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("CAB1")
Dim xNumber As Long
xNumber = ThisWorkbook.Worksheets("NIM & BADGER").Range("R27").Value
Dim i As Long
For i = 1 To xNumber
ws.Copy After:=ThisWorkbook.Sheets(ws.Index + i - 1)
ThisWorkbook.Sheets(ws.Index + i).Name = "CAB" & i + 1
Next
ws.Activate
Application.ScreenUpdating = True
End Sub
Before running the code:
After running the code:
You could also built in a test if the worksheet already exists and ask the user if it should be deleted:
Option Explicit
Public Sub CABsheet()
Application.ScreenUpdating = False
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("CAB1")
Dim xNumber As Long
xNumber = 10
Dim i As Long
For i = 1 To xNumber
ws.Copy After:=ThisWorkbook.Sheets(ws.Index + i - 1)
If WorksheetExists("CAB" & i + 1) Then
If MsgBox("Worksheet '" & "CAB" & i + 1 & "' already exists. Do you want to delete it?", vbExclamation + vbYesNo) = vbYes Then
Application.DisplayAlerts = False
ThisWorkbook.Sheets("CAB" & i + 1).Delete
Application.DisplayAlerts = True
ThisWorkbook.Sheets(ws.Index + i).Name = "CAB" & i + 1
End If
Else
ThisWorkbook.Sheets(ws.Index + i).Name = "CAB" & i + 1
End If
Next
ws.Activate
Application.ScreenUpdating = True
End Sub
Public Function WorksheetExists(ByVal WorksheetName As String, Optional ByVal InWorkbook As Workbook) As Boolean
If InWorkbook Is Nothing Then
Set InWorkbook = ThisWorkbook
End If
On Error Resume Next
Dim ws As Worksheet
Set ws = InWorkbook.Worksheets(WorksheetName)
On Error GoTo 0
WorksheetExists = Not ws Is Nothing
End Function