Send an email if the cell contains the word "expired" - excel

Question

I would like to use excel to send an email to the email address in column C from C5-C42 when the corresponding cell in column F contains the text "expired". I've been at this for over four days. I appreciate any help I can get.
I also keep getting a run-time error 424.
Below is my code:
Private Sub CommandButton1_Click()
If Target.Cells.Count > 1 Then Exit Sub
If Not Application.Intersect(Range("F5:F42"), Target) Is Nothing Then
If IsNumeric(Target.Value) And Target.Value = "Expired" Then
Call Mail_small_Text_Outlook
End If
End If
End Sub
Sub Mail_small_Text_Outlook()
Dim OutApp As Object
Dim OutMail As Object
Dim strbody As String
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
strbody = "Hi there" & vbNewLine & vbNewLine & _
"Your certification has expired." & vbNewLine & _
"Please contact an admin."
On Error Resume Next
With OutMail
.To = "emailaddress#net.com"
.CC = ""
.BCC = ""
.Subject = "This is the Subject line"
.Body = strbody
.Display
End With
On Error GoTo 0
Set OutMail = Nothing
Set OutApp = Nothing
End Sub

Answer 1

Try this:
Private Sub CommandButton1_Click()
Dim c As Range
For Each c In Range("F5:F42")
If c.Value2 = "Expired" Then Call Mail_small_Text_Outlook(c.Offset(0, -3).Value2)
Next c
End Sub
This first routine is triggered by the command button click. It cycles through each cell in range F5:F42. If the cell has "Expired" as a value, it calls the mail routine, and passes to it the value contained in column C (by using the F column address -3 columns)
Sub Mail_small_Text_Outlook(emailAddress As String)
Dim OutApp As Object
Dim OutMail As Object
Dim strbody As String
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
strbody = "Hi there" & vbNewLine & vbNewLine & _
"Your certification has expired." & vbNewLine & _
"Please contact an admin."
On Error Resume Next
With OutMail
.To = emailAddress
.CC = ""
.BCC = ""
.Subject = "This is the Subject line"
.Body = strbody
.Display
End With
On Error GoTo 0
Set OutMail = Nothing
Set OutApp = Nothing
End Sub
The mail routine accepts an email address as a parameter and hopefully you'll notice it replaces the generic "email address.com" you had on the .To line
Please be aware that currently the code is creating a new instance of Outlook for every time it needs to send an e-mail, without closing it. I think you can quit Outlook simply with the line OutApp.Quit so try sticking that in at the end of the Mail_small_Text_Outlook routine