Changing cell range to cover all data in column - excel

Question

I created a macro in my excel sheet
The aim of the macro is to copy the cells in one column, one by one (L1,L2...), into a specific cell (A1). then after the calculations are done, copy the value from another cell E2, to the column next to L, meaning to M1, M2...
i couldn't know how to loop these steps to all the cells in the column.
Sub Checking_Frequences()
'
' Checking_Frequences Macro
'
'
Range("L1").Select
Selection.Copy
Range("A1").Select
ActiveSheet.Paste
Range("E2").Select
Application.CutCopyMode = False
Selection.Copy
Range("M1").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Range("L2").Select
Application.CutCopyMode = False
Selection.Copy
Range("A1").Select
ActiveSheet.Paste
Range("E2").Select
Application.CutCopyMode = False
Selection.Copy
Range("M2").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
End Sub
is there a way to add a delay, so that excel finish calculations before copying the result from E2?
any advice?
regards

Answer 1

Your workbook can do with a little organisational upgrading. I may not have done it the way you best like but I think the code below will let you take a big step forward. Install it in a standard code module and run only the procedure WriteArrays. Take time to understand how it works first.
Sub WriteArrays()
' 043
' number of results wanted from each Base
Const Iterations As Integer = 5 ' adjust to suit
Const TgtTab As String = "Sheet3" ' Output tab (change to suit)
Const TgtRow As Long = 2 ' modify to suit
Const TgtClm As Long = 4 ' first output column (modify to suit)
Dim Src As Variant ' array of source Base numbers
Dim R As Long ' SrcRng row counter
Dim WsTgt As Worksheet ' Target worksheet (for output)
Dim Arr As Variant ' value to write to sheet
Dim Operand As Double ' calculated by a formula
Dim i As Long ' loop counter
Operand = 2 ^ (1 / 12) ' = 1.0594630943593 (adjust to suit)
With Worksheets("Frequencies")
' set the range L1:L(last used row) - modify to suit
' read all values into an array
Src = .Range(.Cells(1, "L"), .Cells(.Rows.Count, "L").End(xlUp)).Value
End With
Set WsTgt = Worksheets(TgtTab)
For R = LBound(Src) To UBound(Src)
Arr = BaseArray(Src(R, 1), Operand, Iterations)
With WsTgt.Cells(TgtRow, TgtClm - 1 + R).Resize(UBound(Arr))
.Value = Application.Transpose(Arr)
.NumberFormat = "0.00"
End With
' If R = 5 Then Exit For
Next R
End Sub
Private Function BaseArray(ByVal Base As Double, _
ByVal Operand As Double, _
ByVal Iterations As Integer) As Variant
' 043
Dim Fun As Variant ' function return value
Dim i As Integer
ReDim Fun(1 To Iterations)
For i = LBound(Fun) To UBound(Fun)
Fun(i) = Base
Base = Round(Base * Operand, 2)
Next i
BaseArray = Fun
End Function
There are 4 constants at the top of the code which you will have to set. The last 3 deal with the output. You asked for output in column M on the same sheet. But this code will add 235 columns. So I thought it better to start a new sheet. You can easily run the code multiple times with different parameters and output the results on different sheets. But they must exist before the code is run.
Const Iterations specifies how many rows there will be in each column. You seem to want 50. I tested with only 5. Modify this constant to suit your needs.
A little further down there is the Operand which is the formula taken from your cell C1. It can be changed.
Of course, the tab Frequencies must exist and it must have numbers in column L. You can start from row 2 instead of 1. But if you want to limit the output you may like to avail yourself of the method I used, here: If R = 5 Then Exit For (at the end of the Next ../.. For loop). It just curtails the loop after 5 numbers from the list, if you enable the line by removing the leading apostrophe.
I wish you the best of luck with your venture :-)