Get specific items values from a dictionary key - excel

Question

I have this table (just few rows) that is loaded to a dictionary.
I have a this class module 'clsTicket'
Public Field As String
Public row As Long
Public cell As String
Public Tabs As String
Public Required As String
This function shows all the items for the key, ind this case 'Ticket_Field3'
Call getDictKeyValuesAll(oDict, "Ticket_Field3")
Function getDictKeyValuesAll(oDict As Object, key As Variant) As Object
' Checks for the key exists
If Not oDict.Exists(key) Then Exit Function
Dim rgOut As Range
Set rgOut = Sheet1.Range("A2").CurrentRegion
Dim oTicket As clsTicket
Set oTicket = oDict(key)
With oTicket
' Write out the values
rgOut.Cells(1, 1).Value = key
rgOut.Cells(1, 2).Value = .row
rgOut.Cells(1, 3).Value = .cell
rgOut.Cells(1, 4).Value = .Tabs
rgOut.Cells(1, 5).Value = .Required
End With
Set getDictKeyValuesAll = oDict
End Function
So far so good and it works as expected.
Now I would like to make a new function to return just a few items, not all items. I thought of using a ParamArray and try to get the values for "Row" and "Cell" for the key "Ticket_Field3". I tried to create the function below with a For loop, but I don't know how to get to each item specifically.
Any suggestion?
Call ShowDictKeyValues(oDict, "Ticket_Field3", "Row", "Cell")
Function getDictKeyValues(oDict As Object, key As Variant, ParamArray arrValues() As Variant) As Object
' Checks for the key exists
If Not oDict.Exists(key) Then Exit Function
Dim rgOut As Range
Set rgOut = wsTicket.Range("A2")
Dim oTicket As clsTicket
Set oTicket = oDict(key)
Dim vArg As Variant, icount As Integer
For icount = 0 To UBound(arrValues)
vArg = arrValues(icount)
rgOut.Cells(1, icount + 1).Value = oDict.Item(vArg)
Next icount
End Function

Answer 1

First, as #Scott Holtzman has already mentioned, you can pass Array("Row", "Cell") to getDictKeyValues instead. So you can replace ParamArray arrValues() As Variant with arrValues As Variant.
Function getDictKeyValues(oDict As Object, key As Variant, arrValues As Variant) As Object
Then you can use CallByName to return the values for each of the specified property names for the class object.
CallByName(oTicket, arrValues(iCount), VbGet)
By the way, since you're not actually returning anything, you can change your function to a sub.
Called Procedure
Sub getDictKeyValues(oDict As Object, key As Variant, arrValues As Variant)
' Checks for the key exists
If Not oDict.Exists(key) Then Exit Sub
Dim rgOut As Range
Set rgOut = wsTicket.Range("A2")
Dim oTicket As clsTicket
Set oTicket = oDict(key)
Dim iCount As Integer
For iCount = LBound(arrValues) To UBound(arrValues)
rgOut.Cells(1, iCount + 1).Value = CallByName(oTicket, arrValues(iCount), VbGet)
Next iCount
End Sub
Call to Procedure
Call getDictKeyValues(oDict, "Ticket_Field3", Array("Row", "Cell"))