CountIf results in "0" - excel

Question

I need help for one part of my complete code. The code below should count the rows that meet the defined conditions for every month. The problem is that I only get "0" as result. I cant figure out why? Is it maybe because of my date format? My source wb contains dates in a format like "01.01.2019".
The code should also only count rows from the first of any month. Meaning: 01.01., 01.02.,01.03. etc.
My master workbook(wb) has an user form with file explorer function, where I can choose my source workbook(wbSource) and apply the macro on it. As seen in the complete code below.
Any help would be appreciated.
Dim x As Long
For x = 1 To 12
ws.Cells(8, 1 + x) = _
Application.WorksheetFunction.CountIfs(wsSource.Columns(8), Format(x, "00") & "." & MonthName(x), _
wsSource.Columns(30), "<=" & 50)
ws.Cells(9, 1 + x) = _
Application.WorksheetFunction.CountIfs(wsSource.Columns(8), Format(x, "00") & "." & MonthName(x), _
wsSource.Columns(30), ">" & 50, wsSource.Columns(30), "<=" & 100)
ws.Cells(10, 1 + x) = _
Application.WorksheetFunction.CountIfs(wsSource.Columns(8), Format(x, "00") & "." & MonthName(x), _
wsSource.Columns(30), ">" & 100)
Next x
Complete Code
Private Sub CommandButton2_Click() ' update averages
Const YEAR = 2019
' open source workbook
Dim fname As String, wbSource As Workbook, wsSource As Worksheet
fname = Me.TextBox1.Text
If Len(fname) = 0 Then
MsgBox "No file selected", vbCritical, "Error"
Exit Sub
End If
Set wbSource = Workbooks.Open(fname, False, True) ' no link update, read only
Set wsSource = wbSource.Sheets("Sheet1") ' change to suit
Dim wb As Workbook, ws As Worksheet
Set wb = ThisWorkbook
Set ws = wb.Sheets("Table 2") '
' scan down source workbook calc average
Dim iRow As Long, lastRow As Long
Dim sMth As String, iMth As Long
Dim count(12) As Long, sum(12) As Long
lastRow = wsSource.Cells(Rows.count, 1).End(xlUp).Row
For iRow = 1 To lastRow
If IsDate(wsSource.Cells(iRow, 8)) _
And IsNumeric(wsSource.Cells(iRow, 30)) Then
iMth = Month(wsSource.Cells(iRow, 8)) ' col H
sum(iMth) = sum(iMth) + wsSource.Cells(iRow, 30) ' Col AD
count(iMth) = count(iMth) + 1 '
End If
Next
' counting the rows
Dim x As Long
For x = 1 To 12
ws.Cells(8, 1 + x) = _
Application.WorksheetFunction.CountIfs(wsSource.Columns(8), Format(x, "00") & "." & MonthName(x), _
wsSource.Columns(30), "<=" & 50)
ws.Cells(9, 1 + x) = _
Application.WorksheetFunction.CountIfs(wsSource.Columns(8), Format(x, "00") & "." & MonthName(x), _
wsSource.Columns(30), ">" & 50, wsSource.Columns(30), "<=" & 100)
ws.Cells(10, 1 + x) = _
Application.WorksheetFunction.CountIfs(wsSource.Columns(8), Format(x, "00") & "." & MonthName(x), _
wsSource.Columns(30), ">" & 100)
Next x
' close source worbook no save
wbSource.Close False
' update Table 2 with averages
With ws.Range("A3")
For iMth = 1 To 12
.Offset(0, iMth - 1) = MonthName(iMth) & " " & YEAR
If count(iMth) > 0 Then
.Offset(1, iMth - 1) = sum(iMth) / count(iMth)
.Offset(1, iMth - 1).NumberFormat = "0.0"
End If
Next
End With
Dim msg As String
msg = iRow - 1 & " rows scanned in " & TextBox1.Text
MsgBox msg, vbInformation, "Table 2 updated"
End Sub
Result-Sheet in Wb - as you see there are only zeroes displayed in the number of rows table
Example of wb.Source - Columns H(8) and AD(30) are the only relevant one for the ounting of the rows. In the example belows the last row should not be counted as the date does not match the condition ( its not the first of the month).

Answer 1

Yes, the problem is from the way you handle the dates. Your data has true dates. They aren't random numbers but a count of days since Jan 1, 1900. They uniquely identify every day for the past 120 years, and the system will continue to identify every day for the next 120 years, too. I believe the code below will do, more or less, what you intended to do.
Sub WriteCountIf()
' 025
' The YearCell must contain a year number like 2019.
Const YearCell As String = "A1" 'change to suit
Dim DateRng As Range ' the range to search for dates in
Dim DaysRng As Range ' the range to search for days in
Dim StartDate As Date ' first day to include in count
Dim EndDate As Date ' last day to include in count
Dim C As Long ' the column to write to (= month)
With ActiveSheet ' better to define the sheet by name
' make sure your result range doesn't overlap the search ranges
Set DateRng = .Range(.Cells(11, 8), .Cells(.Rows.Count, 8).End(xlUp))
Set DaysRng = .Range(.Cells(11, 30), .Cells(.Rows.Count, 30).End(xlUp))
For C = 1 To 12
StartDate = DateSerial(.Range(YearCell).Value, C, 1)
EndDate = DateSerial(Year(StartDate), C + 1, 0)
.Cells(8, 1 + C).Value = Application.WorksheetFunction. _
CountIfs(DateRng, ">=" & StartDate, _
DateRng, "<=" & EndDate, _
DaysRng, "<=" & 50)
.Cells(9, 1 + C).Value = Application.WorksheetFunction. _
CountIfs(DateRng, ">=" & StartDate, _
DateRng, "<=" & EndDate, _
DaysRng, ">" & 50, _
DaysRng, "<=" & 100)
.Cells(10, 1 + C).Value = Application.WorksheetFunction. _
CountIfs(DateRng, ">=" & StartDate, _
DateRng, "<=" & EndDate, _
DaysRng, ">" & 100)
Next C
End With
End Sub
It seems that your data only show day and month. That's a matter of display (cell formatting). The underlying dates include the year. Therefore you need a year when you search them. I have added a year in A1. You can move that cell to anywhere or hard-program a year into the code.
Your definition of search ranges, just by columns, is insufficient, and it overlaps with the cells into which you want to write the counts. I have assumed a start row and my code finds the end of each column. Please try it out.

Answer 2

In the code below the counting procedure is converted into a function that returns its result as an array. This is called by the main procedure and written to the worksheet. I couldn't test the code en total but the part described above works as advertised.
Private Sub CommandButton2_Click() ' update averages
' "Year" is the name of a VBA function.
' To use the same word here as a variable name is asking for trouble.
Const Year As Integer = 2019
Dim wbSource As Workbook, wsSource As Worksheet
Dim Wb As Workbook, Ws As Worksheet
Dim fname As String
fname = Me.TextBox1.Text
If Len(fname) = 0 Then
MsgBox "No file selected", vbCritical, "Error"
Exit Sub
End If
Set Wb = ThisWorkbook
Set Ws = Wb.Sheets("Table 2") '
' open source workbook
Set wbSource = Workbooks.Open(fname, False, True) ' no link update, read only
Set wsSource = wbSource.Sheets("Sheet1") ' change to suit
Dim iRow As Long, lastRow As Long
Dim sMth As String, iMth As Long
Dim count(12) As Long, sum(12) As Long ' Confusing: Count is a VBA method
' scan down source workbook calc average
' observe how .Rows.count is written with lower case c
' because of your declaration of "count" in that way
lastRow = wsSource.Cells(wsSource.Rows.count, 1).End(xlUp).Row
For iRow = 1 To lastRow
If IsDate(wsSource.Cells(iRow, 8)) And _
IsNumeric(wsSource.Cells(iRow, 30)) Then
iMth = Month(wsSource.Cells(iRow, 8)) ' col H
sum(iMth) = sum(iMth) + wsSource.Cells(iRow, 30) ' Col AD
count(iMth) = count(iMth) + 1
End If
Next
' counting the rows
Ws.Cells(8, 2).Resize(3, 12).Value = RowsCount(Year, wsSource)
' close source worbook no save
wbSource.Close False
' update Table 2 with averages
With Ws.Range("A3")
For iMth = 1 To 12
.Offset(0, iMth - 1) = MonthName(iMth) & " " & Year
If count(iMth) > 0 Then
.Offset(1, iMth - 1) = sum(iMth) / count(iMth)
.Offset(1, iMth - 1).NumberFormat = "0.0"
End If
Next
End With
Dim msg As String
msg = iRow - 1 & " rows scanned in " & TextBox1.Text
MsgBox msg, vbInformation, "Table 2 updated"
End Sub
Private Function RowsCount(ByVal RefYear As Integer, _
Ws As Worksheet) As Variant
' 025
Dim Fun As Variant ' Function return value
Dim DateRng As Range ' the range to search for dates in
Dim DaysRng As Range ' the range to search for days in
Dim StartDate As Date ' first day to include in count
Dim EndDate As Date ' last day to include in count
Dim C As Long ' the column to write to (= month)
With Ws
' make sure your result range doesn't overlap the search ranges
Set DateRng = .Range(.Cells(11, 8), .Cells(.Rows.count, 8).End(xlUp))
Set DaysRng = .Range(.Cells(11, 30), .Cells(.Rows.count, 30).End(xlUp))
End With
ReDim Fun(1 To 3, 1 To 12)
For C = 1 To 12
StartDate = DateSerial(RefYear, C, 1)
EndDate = DateSerial(Year(StartDate), C + 1, 0)
Fun(1, C) = Application.WorksheetFunction. _
CountIfs(DateRng, ">=" & StartDate, _
DateRng, "<=" & EndDate, _
DaysRng, "<=" & 50)
Fun(2, C) = Application.WorksheetFunction. _
CountIfs(DateRng, ">=" & StartDate, _
DateRng, "<=" & EndDate, _
DaysRng, ">" & 50, _
DaysRng, "<=" & 100)
Fun(3, C) = Application.WorksheetFunction. _
CountIfs(DateRng, ">=" & StartDate, _
DateRng, "<=" & EndDate, _
DaysRng, ">" & 100)
Next C
RowsCount = Fun
End Function
Capitalization is very important in VBA. As the example of your use of the Count word demonstrates VBA will try to adapt to your style. Therefore, if you have no system you will destroy VBA's. The theory I follow is to use caps and smalls on all variable names. Then I type using only lower case. VBA will correct my typing and this serves as a spell checker, helping to avoid typos. There are a few exceptions to this but that's the general rule I follow.
It's the same with the choice of variable names. Generally I avoid using words VBA uses. That prevents confusion for me (never mind VBA). But if I do use VBA's words I follow the existing capitalization.