VBA - looking for solution to my simple dynamic looping sum calculation - excel

Question

I'm a novice trying to learn VBA. I've got a looping question: I have a simple set of numbers that are grouped in rows of three. I'm hoping to sum them up individually in column f. How could I create a dynamic range in order to loop through these to get the totals?
layout and workings are below - I don't think I have my dynamic range formula correct either. Any help is gratefully appreciated:
basic test data
Sub testing1000b()
Dim rng As Range
Dim lAnswer As Long
Dim lastrow As Long
Dim firstrow As Long
Dim addrow As Long
Range("e:f").ClearContents
addrow = 6
firstrow = Range("b" & addrow).Row
lastrow = Range("b" & firstrow).End(xlDown).Row
Range("b & firstrow" & "b & lastrow") = rng
lAnswer = WorksheetFunction.Sum(rng)
Range("f6").Value = lAnswer
End Sub

Answer 1

Sum Up Consecutive Cells
Sub SumConsecutive()
Const SourceCol As Long = 2
Const ResultCol As Long = 6
Const InitialRow As Long = 6
Const Consecutive As Long = 3
Dim rng As Range
Dim FirstRow As Long
Dim LastRow As Long
Dim Result As Long
Dim RowDiff As Long
Columns(ResultCol).ClearContents
FirstRow = InitialRow
LastRow = Cells(FirstRow, SourceCol).End(xlDown).Row
RowDiff = LastRow - FirstRow
Do Until RowDiff <> Consecutive - 1
Set rng = Range(Cells(FirstRow, SourceCol), Cells(LastRow, SourceCol))
Result = WorksheetFunction.Sum(rng)
Cells(FirstRow, ResultCol).Value = Result
FirstRow = Cells(LastRow, SourceCol).End(xlDown).Row
LastRow = Cells(FirstRow, SourceCol).End(xlDown).Row
RowDiff = LastRow - FirstRow
Loop
MsgBox "Done"
End Sub

Answer 2

You can create a dynamic range with the code bellow.
You need to use [Set] when object is assigned to a variable.
Set rng = Range("b" & firstrow & ":" & "b" & lastrow)
this is a sample code.
Sub testing1000b()
Dim rng As Range
Dim lAnswer As Long
Dim lastrow As Long
Dim firstrow As Long
Dim addrow As Long: addrow = 6
Range("e:f").ClearContents
firstrow = Range("b" & addrow).Row
lastrow = Range("b" & firstrow).End(xlDown).Row
For i = 0 To 3
Set rng = Range("b" & firstrow & ":" & "b" & lastrow)
Range("f" & firstrow) = WorksheetFunction.Sum(rng)
firstrow = Range("b" & lastrow).End(xlDown).Row
lastrow = Range("b" & firstrow).End(xlDown).Row
Next i
End Sub