Filter a column using IF statement in powerquery - excel

Question

I'm having trouble filtering my columns in powerquery. I'm using a parameter to filter my 'Island' NI or SI, however I am struggling to find a way to keep all the data when no parameter is inputted.
I would like to leave the column full (NI and SI) if no input is provided. I've added two pictures on imgur below. I'm fairly new here.
I've tried using an if statement but couldn't figure out the right piece of code or if it's even possible to do so.
Thanks
enter image description here. enter image description here

Answer 1

Note: see the very end for a version that does not need to hard-code values.
First let's test if the search filter is a valid value. If not, don't filter anything.
if IslandChoice is "NI" or "SI"
then filter using IslandChoice
else
show everything
The other route is
if IslandChoice is not "NI" and is not "SI"
show everything
else
filter using IslandChoice
It depends if you want invalid values to show nothing, or everything.
First check "is this filter a valid choice?
[Island] = "SI" or [Island] = "WI"
If either one is true, then it's good. If both are false, then it's an invalid key.
filter_if_valid = Table.SelectRows(
Source,
(row) =>
if IslandChoice = "SI" or IslandChoice = "NI" then
row[Island] = IslandChoice
else
true
)
How does it work, and where is each ?
each is a normal function. It's sugar, a shortcut that declares a function which has a single arugment. (If you need more, use a function declaration)
see more: Details on the grammar of each is in the docs
each implicitly creates the variable named _
Because each abstracts a couple of things, it's harder to tell what's happening.
each creates a variable named _ which references the current row.
each declares a function without the arguments part
Functions follow the form
(arguments) => return_expression
Written using each it removes the (arguments) => portion.
each return_expression
return_expression can be a simple [Column] = 10 test. (Or it can create many local variables using a let .. in expression inside the function).
These statements are all exactly equivelent functions
each [Island] = IslandChoice
each _[Island] = IslandChoice
(_) => _[Island] = IslandChoice
(row) => row[Island] = IslandChoice
They all
declare a function without a name
accept exactly 1 argument
read the column [Island] in the current table row
returns true if they are equal, else false
original filter
after replacing each you had:
always_filter_table = Table.SelectRows(
Source,
(row) =>
row[Island] = IslandChoice
),
new filter
filter_if_valid = Table.SelectRows(
Source,
(row) =>
if IslandChoice = "SI" or IslandChoice = "NI" then
row[Island] = IslandChoice
else
true
)
filter without hard-coding values
This will run alone without any requirements. Create a new -> blank query
let
Source = #table(
{"Island", "Point Of Connection"},
{
{"SI", "STK0331"},
{"SI", "TIM0111"},
{"NI", "ZEJ2395"},
{"NI", "XER9345"},
{"WI", "QXF9785"}
}
),
is_valid_filter = (value as any, valid_values as list) =>
List.Contains( valid_values, value ),
// use one or the other if you want all existing values to be valid
static_valid_filters = {"SI", "NI"},
dynamic_valid_filters = List.Distinct(
Source[Island]
),
IslandChoice = "NI",
// if filter is a valid value, filter using it.
// otherwise show all.
filtered_when_valid = Table.SelectRows(
Source,
(row) =>
if is_valid_filter(
IslandChoice, static_valid_filters
) then
row[Island] = IslandChoice
else
true
)
in
filtered_when_valid