Changing values in multiple columns using Select Case - excel

Question

I am trying to reset the document to default based on the value in Column E or 5. I would then like to change the value of the cell in both column 5 and 7.
When I run without the Cells (x,7) lines it works.
Sub Reset_Submitted_Document_HW_ALSTOM()
ActiveSheet.Unprotect
Dim answer As Integer
answer = MsgBox("Do you want to reset the Submittted Document for Sign Of Year? This is typically performed at year end to clear the tracker.", vbQuestion + vbYesNo + vbDefaultButton2, "Reset Submitted Document Checkmark")
If answer = vbYes Then
Application.ScreenUpdating = False
For x = 1 To Cells(Rows.Count, "E").End(xlUp).Row
Select Case (Cells(x, 5))
Case "Reset Default Date"
Cells(x, 5) = "Reset Default Date"
Cells(x, 7).Formula = "=Today()"
Case "Final Update"
Cells(x, 5) = "Reset Default Date"
Cells(x, 7).Formula = "=Today()"
Case "Final Action Taken SPD"
Cells(x, 5) = "Populate Previous SPD"
Cells(x, 7) = ""
Case "Populate Previous SPD"
Cells(x, 5) = "Populate Previous SPD"
Cells(x, 7) = ""
Case Else
Cells(x, 5).Formula = "="""""
End Select
Next x
Application.ScreenUpdating = True
Else
MsgBox "No Updates have been made to the tracker."
End If
ActiveSheet.Protect
End Sub
Update: The answered code runs but does not change the date, nor reset cells in column E that say "Final Update" to "Reset Default Date". I'm thinking it may have something to do with xlUp stopping part way down column E.
Screenshot of how the sheet is structured.

Answer 1

Some Minor Corrections
If you don't use Option Explicit (not recommended), there is no error. When you use it, there is a compile error because x isn't dimmed.
The lines that contain .formula should be changed, because e.g. the data will be changed to the date when you open the workbook again, but you need the date when the reset was done. Similarly you don't want the formula ="" in a column with only values.
If you want to do the same thing for two conditions in a Select Case statement, you separate them by a comma in the same case. The comma means Or.
If the code stops in the middle, ScreenUpdating will stay False. Do some Error handling.
Option Explicit
Sub Reset_Submitted_Document_HW_ALSTOM()
ActiveSheet.Unprotect
Dim answer As Long
Dim x As Long
answer = MsgBox("Do you want to reset the Submittted Document " _
& "for Sign Of Year? This is typically performed at year end to clear " _
& "the tracker.", vbQuestion + vbYesNo + vbDefaultButton2, _
"Reset Submitted Document Checkmark")
If answer <> vbYes Then MsgBox _
"No Updates have been made to the tracker.": GoTo ProgramExit
Application.ScreenUpdating = False
On Error GoTo ProgramError
For x = 1 To Cells(Rows.Count, "E").End(xlUp).Row
Select Case (Cells(x, 5))
Case "Reset Default Date", "Final Update"
Cells(x, 5) = "Reset Default Date"
Cells(x, 7) = Date ' Cells(x, 7).Formula = "=Today()"
Case "Final Action Taken SPD", "Populate Previous SPD"
Cells(x, 5) = "Populate Previous SPD"
Cells(x, 7) = ""
Case Else
Cells(x, 5) = "" 'Cells(x, 5).Formula = "="""""
End Select
Next
SafeExit:
Application.ScreenUpdating = True
ProgramExit:
ActiveSheet.Protect
Exit Sub
ProgramError:
MsgBox "An unexpected error occurred."
On Error GoTo 0
GoTo SafeExit
End Sub