I made a formula in excel, yet when trying it out, it responds with NAME?
=IF(MAAND(VANDAAG()) > MAAND(D1); (NETTO.WERKDAGEN(D1; D3)) * D5; D6)
My goal is to calculate how many Hours I still need This Month in Row 8.
depending on startdate(startdatum and current date (huidige datum) (not enddate(einddatum)) and how many work days there are between those dates times the hours.
Any ideas on how to solve this?
UPDATE
translations:
Maand = Month
Vandaag = Today
Netto.WerkDagen = NETWORKDAYS
Solved. I had to use ALS (dutch translation).....
Related
struggling to find anything on here regarding my query, which leads me to believe it may be impossible but here goes!
my company creates products that take takes around two weeks to fully build from start to finish. The whole company works in weeks and days, for example we would start building on week 14.1 (14th week and on Monday) and finish building on week 16.5 (16th week and on Friday). The company is massive so I cannot convert them to use dates instead.
We want to capture data from a spreadsheet that has 5 columns, A = build week , B = build day, C = Completion week, D = Completion day, E = calendar days.
At present we just manually work out the amount of calendar days as it is difficult to write a formula to differentiate between knowing week 52.5 and week 1.1 is only 4 days.
is it possible to write a formula or use a VBA code to work out the amount of calendar days between two week numbers from the data I have or am I testing the limits of excel?
any help would be great.
Use:
=((C2+(C2<A2)*52)*7+D2)-(A2*7+B2)+1
I am trying create a data set and finding it difficult to do it manually. I just wanted to know if there is way we can do it automatically in Excel.
I am trying to calculate the week difference with reference current year & calendar week.
Below is the formula used to calculate current year & calendar week
=YEAR(TODAY())&WEEKNUM(NOW()) Result would be 201840
I am expecting the weekdiff calculation as shown below. Any help in this regard would be deeply appreciated.
Thanks,
Ganesh
I would try to convert Year/Week to the overall week since 0 A.D. and then subtract. This may need some adjustment for Leap years.
=(YEAR(TODAY()) * 52) + WEEKNUM(NOW()) - (VALUE(LEFT(A2,4))* 52) - VALUE(RIGHT(A2,2))
This task seems easy enough yet I just can't figure a way of doing this without resorting to vba.
All I need is to know the number of hours an employee has used up on annual leave, based on a start and end date, and their hours of work.
To be more clear, this example shows one employees contracted hours from Monday to Sunday i.e. they work only Weds, Thurs, and Friday, for 7.5 hours each day.
Below shows the start and end date that the employee has chosen to take for annual leave. I need to calculate, based on their contracted hours, how much annual leave is used between the two dates. The answer would be 45 hours in this case.
Here's another approach - I've expanded the days between the start and end dates into an array then used the resulting day numbers to offset into the days of work range
=SUMPRODUCT(N(OFFSET(A3,0,WEEKDAY(ROW(INDIRECT(A6&":"&B6)),2)-1)))
If you had a list of holiday dates somewhere (say in I3:N3) you could exclude them as follows
=SUMPRODUCT(N(OFFSET(A3,0,WEEKDAY(ROW(INDIRECT(A6&":"&B6)),2)-1))*ISNA(MATCH(ROW(INDIRECT(A6&":"&B6)),I3:N3,0)))
- it is a bit long-winded but the only way I can think of at the moment.
I'm stuck creating a formula that will calculate days before the end of the month then adjust to make sure it is a business day. For example: 30 days before 6/30/2015 is 5/31/2015 which is a Sunday. I need that to adjust to the Friday before.
I'm working on finding the due dates of a number of documents that are due a certain number of days before another date. For example: documents are due 30 days before the last day of the month. However, the number of days varies and the due date needs to fall on a business day (Monday-Friday). Sometimes it's 30 days, sometimes it's 60 days, sometimes it's 30 calendar days + 5 business days, etc.
I've been able to calculate 30 days + 5 business days with the following formula:
=workday(start_date-30,-5)
Any ideas how to adjust this so that I can just have the due date be 30 calendar days before a certain date but also always be a business day?
Using WORKDAY you can use a formula like this:
=WORKDAY(A1+B1+1,-1)
where A1 is your start date and B1 the number of days to add.
You probably need to write a macro function or maybe some nested IF statements in your cell's formula.
Take a look at http://www.mrexcel.com/forum/excel-questions/481558-round-date-nearest-workday.html
That solution moves forward to the nearest workday, but the principle is sound: just subtract instead of add.
This sounds simple but I have been pulling my hair out trying to figure out a solution. Any help before I go bald would be great.
I need a formula which is able to
calculate the duration in (days, hrs, mins) between two date\time values (eg 05/12/2012 5:30 PM and say 07/12/2012 5:45 PM);
excluding weekends and holidays.
I would like the result of the formula to read as follows "e.g 2 Days 0 Hrs and 15 Mins".
Thanks
Link to sample workbook
You can use NETWORKDAYS and NETWORKDAYS.INTL to achieve this
A bit of manipulation is required as these return net whole days:
Use these functions to calculate the number of non workdays, then subtract from the difference between start and end dates
=E3-D3-(NETWORKDAYS.INTL(D3,E3,"0000000")-NETWORKDAYS(D3,E3,$A$16:$A$24))
This returns the working day difference, where 1.0 = 1 day
NETWORKDAYS.INTL(D3,E3,"0000000") calculates whole days between the two dates (no weekends, no holidays)
NETWORKDAYS(D3,E3,"0000000",$A$16:$A$24) calculates whole working days days between the two dates (Sat/Sun weekends, holidays as per your list in $A$16:$A$24)
Difference in non-working days between the two dates.
E3-D3 is time between start and end date/times (1.0 = 1 day)
Use custom number formatting to display thye result in the format you require
d "Days" h "Hours" mm "Mins"
Note: this format won't work for negative values, you will need an alternative for when end date is before start date.
The following formula works like a treat with no additional formatting or manipulation.
To make it more stable I have turned all the holiday dates for UK 2012/13 into ‘Excel Serial Number’ format and placed them in an array bracket.
Replacing the "D5" in the formula with your cell reference for your course or metric "End Date" and "E5" with your course or Metric for "Completion Date".
=IF(E5<D5,"-"&TEXT(D5-E5,"h:mm"),NETWORKDAYS(D5,E5,({40910,41005,41008,41036,41064,41065,41148,41268,41269,41275,41362,41365,41400,41421,41512,41633,41634}))-1-(MOD(E5,1)<MOD(D5,1))&" days "&TEXT(E5-D5,"h:mm"))