Prime Number for n value - excel

Question

Task: A prime number (or a prime) is a natural number greater than 1 that has no positive
divisors other than 1 and itself. Here are the first few prime numbers:
2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31...
Define a function that, given an integer n, determines the first n prime
numbers.
Problem: I am currently getting the primes between 0-n but not n prime numbers.
My code is:
Sub MACRO()
Z = InputBox("enter number")
Dim x As Long, n As Long, i As Long, PrimeNumber As Long
x = 0
With ActiveSheet
For n = 1 To Z
For i = 2 To n - 1
If n Mod i = 0 Then
x = 0
Exit For
Else
x = 1
End If
Next
If x = 1 Then
PrimeNumber = PrimeNumber + 1
.Cells(PrimeNumber, 1) = n
End If
Next
End With
End Sub

Answer 1

When searching for Primes, you speed thing up by observing:
You only need to test Odd numbers
You can exclude a test for divisibility by 2
You only need to test for divisibility by previously found prime numbers
You only need to test up to the square root of the candidate number
Something like this
Sub FindPrimes(NumPrimes As Long, Primes() As Long)
Dim Candidate As Long, Factor As Long
Dim idxP As Long
Dim IsPrime As Boolean
Dim i As Long
ReDim Primes(1 To NumPrimes)
Primes(1) = 2
Primes(2) = 3
idxP = 3
Candidate = 3
Do While idxP <= NumPrimes
Candidate = Candidate + 2
i = 2
IsPrime = True
Do
Factor = Candidate \ Primes(i)
' Factor < Primes(i) implies Primes(i) > Sqrt(Candidate)
If Factor < Primes(i) Then
Exit Do
End If
If Factor * Primes(i) = Candidate Then
IsPrime = False
Exit Do
End If
i = i + 1
Loop
If IsPrime Then
Primes(idxP) = Candidate
idxP = idxP + 1
End If
Loop
End Sub
Use it like this
Sub Demo()
Dim Primes() As Long
Dim Num As Long
FindPrimes Num, Primes
' Primes is now an array of the first Num primes
End Sub
On my hardware, this finds the first 10,000 primes in 50ms (FWIW, compared to Foxfire's answer which takes 10s)

Answer 2

For this code to work, you need to add a reference to Microsoft Scripting Runtime from Tools->References
Iterate from 1 to number studied.
Dim n As Integer
Dim i As Double
Dim MyStart As Double
Dim zz As Integer
Dim MyPrimes As Dictionary
Dim MyKey As Variant
n = 10 'change this to get n prime numbers
Set MyPrimes = New Dictionary
zz = 0
i = 1
Do Until zz = n
For MyStart = 1 To i Step 1
If i / MyStart = Int(i / MyStart) Then
'check if it's prime
If MyStart = i Then
'it's prime. we check the dictionary. If it does not exist, we add it and update count
If MyPrimes.Exists(MyStart) = False And MyStart<>1 Then
MyPrimes.Add MyStart, MyStart
zz = MyPrimes.Count
End If
Else
'it is not prime. Quit Loop if divisor it's not 1
If MyStart <> 1 Then Exit For
End If
End If
Next MyStart
i = i + 1
Loop
For Each MyKey In MyPrimes.Keys
Debug.Print MyPrimes(MyKey)
Next MyKey
MyPrimes.RemoveAll
Set MyPrimes = Nothing
In the debug windows i Get:
1
2
3
5
7
11
13
17
19
23
Just change n and test it. Hope this helps
UPDATE: As #PeH said, 1 is not prime, my bad,so I updated code to ignore number 1 :)
UPDATE 2: As #PeH suggested, you can also Dim MyPrime As Object and then use late binding Set MyPrime = CreateObject("Scripting.Dictionary").
Advantage: you don't need to add Microsoft Scripting Runtime and if you use it on different computers with different versions of the runtime it will still work.
Disatvantage: you lose intelli sense in the VBA editor (for this object only).
In case you want to know how dictionaries work: Excel VBA Dictionary– A Complete Guide