Pass argument with Vba excel in .onAction in excel 2016 - excel

Question

I am Trying to pass the value i.e sArg with the onAction.But Im not able to do so.
I have tried like this: "'btnT """ & sArg & """'" But this doesn't work.
For i = 3 To LastRow Step 1
Set t2 = ActiveSheet.Range(Cells(i, LastCol + 3), Cells(i, LastCol + 3))
Set btn2 = ActiveSheet.Buttons.Add(t2.Left, t2.Top, t2.Width, t2.Height)
sArg = CStr(i)
With btn2
.OnAction = "Sheet1.btnT"
.Caption = "View " & i
.Name = CStr(i)
End With
Next i
Then the function is
Sub btnT(Text)
MsgBox Text
Exit Sub

Answer 1

You just have to enclose the single and possibly double quotes.
If the argument is numeric (eg 1), use
.OnAction = "'SubName 1'"
If the argument is a string then use
.OnAction = "'SubName ""SomeText""'"
Sub Demo()
Dim i As Long
Dim Arg As Variant
Dim t2 As Range
Dim btn2 As Button
For i = 3 To 4 Step 1
Set t2 = ActiveSheet.Range(Cells(i, LastCol + 3), Cells(i, LastCol + 3))
Set btn2 = ActiveSheet.Buttons.Add(t2.Left, t2.Top, t2.Width, t2.Height)
Arg = i '<~~ adjust to suit your needs
With btn2
.Caption = "View " & i
.Name = CStr(i)
If IsNumeric(Arg) Then
.OnAction = "'Sheet1.btnT " & Arg & "'"
Else
.OnAction = "'Sheet1.btnT """ & Arg & """'"
End If
End With
Next i
End Sub
Sub btnT(Arg As Variant)
MsgBox Arg
End Sub