Deselecting a chart in Excel VBA - excel

Question

In reference to the following file.xlsm:
where Sheet1 (1) is a Sheet, Plot1 (2) is a Graphic-Sheet and the button (3) refers to the following Macro:
Sub plot()
ReDim blue(1 To 5, 1 To 2)
ReDim red(1 To 5, 1 To 2)
For i = 1 To 5
blue(i, 1) = i
blue(i, 2) = i ^ 2
red(i, 1) = i + 4
red(i, 2) = (i + 4) ^ 2
Next i
Sheets("Plot1").Select
ActiveChart.ChartArea.ClearContents
ActiveChart.ChartArea.Select
ActiveChart.ChartType = xlXYScatterSmoothNoMarkers
ActiveChart.SeriesCollection.NewSeries
ActiveChart.FullSeriesCollection(1).XValues = Application.Index(blue, , 1)
ActiveChart.FullSeriesCollection(1).Values = Application.Index(blue, , 2)
ActiveChart.FullSeriesCollection(1).Select
Selection.Format.Line.ForeColor.RGB = RGB(0, 0, 255)
ActiveChart.SeriesCollection.NewSeries
ActiveChart.FullSeriesCollection(2).XValues = Application.Index(red, , 1)
ActiveChart.FullSeriesCollection(2).Values = Application.Index(red, , 2)
ActiveChart.FullSeriesCollection(2).Select
Selection.Format.Line.ForeColor.RGB = RGB(255, 0, 0)
Sheets("Plot1").Protect DrawingObjects:=True, Contents:=False
Sheets("Plot1").Unprotect
Sheets("Sheet1").Select
End Sub
after opening file.xlsm, clicking (3) and (2) I get:
after opening file.xlsm, clicking (2), (1), (3) and (2) I get:
How can I change the Macro so that I always get the third image regardless of the click sequence?

Answer 1

It used to be possible to deselect a chart, that is, an embedded chart, but I don't remember if it worked on a chart sheet.
For some reason, no matter what I try, the chart area becomes selected when this code is first run after opening the workbook. (I even tried activating the chart sheet, then the worksheet, with a Workbook_Open procedure: no luck.) But you can avoid having the second series selected if you don't select it in the first place. Not selecting things actually makes the code run faster, usually not enough that you would notice, but it also prevents the little flash of tabs being activated.
Sub plot()
ReDim blue(1 To 5, 1 To 2) As Double
ReDim red(1 To 5, 1 To 2) As Double
Dim i As Long
For i = 1 To 5
blue(i, 1) = i
blue(i, 2) = i ^ 2
red(i, 1) = i + 4
red(i, 2) = (i + 4) ^ 2
Next i
With Charts("Plot1")
.ChartArea.ClearContents
.ChartType = xlXYScatterSmoothNoMarkers
With .SeriesCollection.NewSeries
.XValues = Application.Index(blue, , 1)
.Values = Application.Index(blue, , 2)
.Format.Line.ForeColor.RGB = RGB(0, 0, 255)
End With
With .SeriesCollection.NewSeries
.XValues = Application.Index(red, , 1)
.Values = Application.Index(red, , 2)
.Format.Line.ForeColor.RGB = RGB(255, 0, 0)
End With
End With
End Sub