Is it possible to have a dynamic sort range? - excel

Question

I was wondering if I can create a macro that sorts my worksheet with a range that is constantly changing? Instead of the last row constantly changing, the top row count will be changing.
Is it possible to have my .setrange be a variable which gets updated with the new range based on arguments?
For example the current code I have sets my range starting at A5 but if rows 6 - 10 have an interior color of green I want it to leave those at the top and only sort starting from A11.
activesheet.Sort.SortFields.Clear
activesheet.Sort.SortFields.Add Key:=Range("M6"), _
SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
With activesheet.Sort
.SetRange Range("A5:O150") ' I want this range to change constantly without me manually changing, for example it would be from ("A10:0150") now
.Header = xlYes
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With

Answer 1

This UDF will return a range object representing your sort range as defined by the first row of data in the fifth column containing a "white" interior (not including the first row, unless that is the ONLY row with a white interior):
Option Explicit
Private Function SortRange(baseRange As Range) As Range
Dim firstCell As Range, lastCell As Range, C As Range
With baseRange
Set lastCell = .Worksheet.Cells(.Row + .Rows.Count - 1, .Column + .Columns.Count - 1)
End With
With Application.FindFormat
.Clear
.Interior.Color = vbWhite
End With
'find the first cell in fifth column that is white
'As implemented, this should be column E, but if you move the range, it will adjust to the 5th column
'after the first row in baseRange
With baseRange
Set firstCell = .Columns(5).Find(what:="*", after:=.Cells(1, 5), searchorder:=xlByRows, searchdirection:=xlNext, searchformat:=True)
If Not firstCell Is Nothing Then
With .Worksheet
Set SortRange = .Range(.Cells(firstCell.Row, 1), lastCell)
End With
Else
MsgBox "no cells to sort"
Exit Function
End If
End With
End Function
You could then use it like:
.SetRange SortRange(activesheet.range("A3:O150"))
but I would suggest replacing activesheet with the actual worksheet.