Find and Filter by String Value - excel

Question

I am pulling a work organization report and want to find and filter by a unique ID value. The unique ID to be filtered is specified by a public property (this number is used on another occasion so that is why it is public) entered through a text box within a userform.
User enters unique ID of manager they want to filter under
Use unique ID to find which manager level column has unique ID
Move onto the next column if ID is not found
Once ID is found, Filter column
There are 9 different manager levels I am filtering through, columns AU, AW, AY, BA ,BC, BE, BG, BI, & BK, and they all rest on row 3. Therefore I have columns 'A3:BK3' but am only filtering between 'AU3:BK3' to pull data in the earlier columns.
++++++Open File Dialog:
```
Private Sub SelectButton_Click()
Dim SelectedFile As String
SelectedFile = Application.GetOpenFilename()
SelectedFiletxtbox = SelectedFile
End Sub
```
++++++Public Property Code:
```
Public Property Get OpenFileTxt() As String
OpenFileTxt = SelectedFiletxtbox.Value
End Property
```
++++++Execution Piece:
```
Private Sub EmailButton_Click()
'Workbooks.Open OpenFile
Application.ScreenUpdating = False
If Len(Trim(Me.EnterWWIDtxtbox.Text)) = 0 Then
Me.EnterWWIDtxtbox.SetFocus
MsgBox "Must provide a Unique ID"
Exit Sub
End If
'WWID = Trim(Me.EnterWWIDtxtbox.Text)
'Path to be pulled from open file dialog as reports are dynamic
Dim ws As Worksheet
Dim wb As Workbook
Set wb = Workbooks.Open(Filename:=OpenFileTxt)
Set ws = wb.Worksheets("Sheet1")
Dim aColumns() As String
aColumns = Split("AU,AW,AY,BA,BC,BE,BG,BI,BK", ",")
Dim bFound As Boolean
bFound = False
Dim rFound As Range
Dim vColumn As Variant
For Each vColumn In aColumns
Set rFound = ws.Columns(vColumn).Find(WWID, , xlValues, xlPart)
If Not rFound Is Nothing Then
bFound = True
MsgBox "Found [" & WWID & "] in column " & vColumn
With ws.Columns(vColumn)
.AutoFilter 1, rFound.Value
MsgBox "filtered"
'Do stuff with the filtered data here
End With
Exit For
End If
Next vColumn
If bFound = False Then MsgBox "Unique ID [" & WWID & "] not found"
'Filter by Region Selected
'Range("AG3").AutoFilter Field:=33, Criteria1:=Region
Unload DistrUserForm
'Open E-Mail
Application.ScreenUpdating = True
End Sub
```

Answer 1

I created a test workbook for this and filled it with junk data. I then created a basic userform that only had a textbox (named txtUniqueID) and a button (named CommandButton1). Entered the ID I was looking for in the textbox and clicked the button to run the search and filter if found. Verified it worked as intended. You should be able to adapt this to your needs. Here's the full userform code. Note the Dim WWID As Variant at the top outside of the sub since you said that was a public variable (this could also have been in a standard module and instead of Dim it would be Public, I just did this for ease of testing).
Dim WWID As Variant
Private Sub CommandButton1_Click()
If Len(Trim(Me.txtUniqueID.Text)) = 0 Then
Me.txtUniqueID.SetFocus
MsgBox "Must provide a Unique ID"
Exit Sub
End If
WWID = Trim(Me.txtUniqueID.Text)
'Explicitly define your workbook and worksheet where the data is
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("Sheet1")
Dim aColumns() As String
aColumns = Split("AU,AW,AY,BA,BC,BE,BG,BI,BK", ",")
Dim bFound As Boolean
bFound = False
Dim rFound As Range
Dim vColumn As Variant
For Each vColumn In aColumns
Set rFound = ws.Columns(vColumn).Find(WWID, , xlValues, xlPart)
If Not rFound Is Nothing Then
bFound = True
MsgBox "Found [" & WWID & "] in column " & vColumn
With ws.Columns(vColumn)
.AutoFilter 1, rFound.Value
MsgBox "filtered"
'Do stuff with the filtered data here
.AutoFilter 'Remove filter afterwards
End With
Exit For
End If
Next vColumn
If bFound = False Then MsgBox "Unique ID [" & WWID & "] not found"
End Sub