Loop over a map and skip empty items - terraform

Question

What I want
In terraform, I have a map service_map:
variable "service_map" {
type = map
description = "Map of some services and their ports."
default = {
"dns" = "53"
"web" = "443"
"ssh" = "22"
"proxy" = ""
}
}
To create LB listeners on AWS, I want to call the resource aws_lb_listener, looping over the map service_map, skipping all items without value (in this case, only proxy):
resource "aws_lb_listener" "listeners" {
for_each = var.service_map
load_balancer_arn = aws_lb.all_lbs[each.key].arn
port = each.value
protocol = each.key != "dns" ? "TCP" : "TCP_UDP"
default_action {
type = "forward"
target_group_arn = aws_lb_target_group.service_map-tg[each.key].arn
}
}
What I tried
Create a second, local map with all key=value pairs where value is not empty:
locals {
service_map_temp = [ for service, port in var.service_map : service, port if port != "" ]
}
Which does not work: Extra characters after the end of the 'for' expression.. And I guess there are smarter solutions than that approach.
Idea: Skipping empty each.values:
resource "aws_lb_listener" "listeners" {
for_each = var.service_map
load_balancer_arn = aws_lb.all_lbs[each.key].arn
port = each.value != "" # Skipping part
protocol = each.key != "dns" ? "TCP" : "TCP_UDP"
default_action {
type = "forward"
target_group_arn = aws_lb_target_group.service_map-tg[each.key].arn
}
}
But I doubt that's going to work because I am still calling the resource but with an empty port, which will fail. Since I am just starting out with terraform, I am sure there is a solution I did not think/read about yet.

Answer 1

Your first solution failed because you have used list brackets [ ... ] but you intend to produce a map. To produce a map from a for expression, use map brackets { ... }:
locals {
service_map_temp = {
for service, port in var.service_map :
service => port if port != ""
}
}
The key difference is that a map for expression expects two expressions after the colon (the key and the value), while the list for expression expects only one.
If you like, you can inline that expression directly in the for_each argument, to keep everything together in one block:
resource "aws_lb_listener" "listeners" {
for_each = {
for service, port in var.service_map :
service => port if port != ""
}
load_balancer_arn = aws_lb.all_lbs[each.key].arn
port = each.value
protocol = each.key != "dns" ? "TCP" : "TCP_UDP"
default_action {
type = "forward"
target_group_arn = aws_lb_target_group.service_map-tg[each.key].arn
}
}

Answer 2

I realized that if you set the parameter to null instead of an empty string "", it will automatically remove the key from the map without having to create a for loop.
variable "service_map" {
type = map
description = "Map of some services and their ports."
default = {
"dns" = "53"
"web" = "443"
"ssh" = "22"
"proxy" = null
}
}
output "service_map" {
value = var.service_map
}
$ terraform apply
Apply complete! Resources: 0 added, 0 changed, 0 destroyed.
Outputs:
service_map = {
"dns" = "53"
"ssh" = "22"
"web" = "443"
}